We are currently migrating Bugzilla to GitHub issues.
Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.
When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.

facelifted configure.in

configure.ac (text/plain), 96.89 KB, created by MatÄ›j TÃ½Ä on 2009-10-05 14:05:49 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: MatÄ›j TÃ½Ä

Created: 2009-10-05 14:05:49 UTC

Size: 96.89 KB

patch

obsolete

>dnl Process this file with autoconf to produce a configure script.
>AC_INIT
>AC_CONFIG_SRCDIR([README])
>AC_CONFIG_HEADER([include/SDL_config.h])
>AC_USE_SYSTEM_EXTENSIONS
>AC_CONFIG_AUX_DIRS($srcdir/build-scripts)
>
>dnl Set various version strings - taken gratefully from the GTk sources
>#
>dnl Making releases:
>dnl Edit include/SDL/SDL_version.h and change the version, then:
>dnl   SDL_MICRO_VERSION += 1;
>dnl   SDL_INTERFACE_AGE += 1;
>dnl   SDL_BINARY_AGE += 1;
>dnl if any functions have been added, set SDL_INTERFACE_AGE to 0.
>dnl if backwards compatibility has been broken,
>dnl set SDL_BINARY_AGE and SDL_INTERFACE_AGE to 0.
>
>SDL_MAJOR_VERSION=1
>SDL_MINOR_VERSION=3
>SDL_MICRO_VERSION=0
>SDL_INTERFACE_AGE=0
>SDL_BINARY_AGE=0
>SDL_VERSION=$SDL_MAJOR_VERSION.$SDL_MINOR_VERSION.$SDL_MICRO_VERSION
>
>AC_SUBST(SDL_MAJOR_VERSION)
>AC_SUBST(SDL_MINOR_VERSION)
>AC_SUBST(SDL_MICRO_VERSION)
>AC_SUBST(SDL_INTERFACE_AGE)
>AC_SUBST(SDL_BINARY_AGE)
>AC_SUBST(SDL_VERSION)
>
>dnl libtool versioning
>LT_INIT([win32-dll])
>
>LT_RELEASE=$SDL_MAJOR_VERSION.$SDL_MINOR_VERSION
>LT_CURRENT=`expr $SDL_MICRO_VERSION - $SDL_INTERFACE_AGE`
>LT_REVISION=$SDL_INTERFACE_AGE
>LT_AGE=`expr $SDL_BINARY_AGE - $SDL_INTERFACE_AGE`
>
>AC_SUBST(LT_RELEASE)
>AC_SUBST(LT_CURRENT)
>AC_SUBST(LT_REVISION)
>AC_SUBST(LT_AGE)
>
>dnl Detect the canonical build and host environments
>AC_CANONICAL_HOST
>AC_C_BIGENDIAN
>AS_IF([test x$ac_cv_c_bigendian = xyes],
>      [AC_DEFINE([SDL_BYTEORDER], 4321, [Description]) ],
>      [AC_DEFINE([SDL_BYTEORDER], 1234, [Description]) ])
>
>dnl Check for tools
>AC_PROG_LIBTOOL
>AC_PROG_CC
>AC_PROG_CXX
>AC_PROG_INSTALL
>AC_PROG_MAKE_SET
>AS_IF([test -z "$host_alias"],
>      [hostaliaswindres=],
>      [hostaliaswindres="$host_alias-windres"])
>dnl TODO:
>dnl LIBTOOL can do this!
>AC_CHECK_PROGS([WINDRES], [windres $hostaliaswindres $host_os-windres])
>
>dnl Set up the compiler and linker flags
>INCLUDE="-I$srcdir/include"
>AS_IF([test x$srcdir != x.],
>      [dnl Remove SDL_config.h from the source directory, since it's the
>       dnl default one, and we want to include the one that we generate.
>       AS_IF([test -f $srcdir/include/SDL_config.h],
>             [rm $srcdir/include/SDL_config.h])
>       INCLUDE="-Iinclude $INCLUDE"])
>AS_CASE(["$host"],
>        [*-*-cygwin*],
>        [dnl We build SDL on cygwin without the UNIX emulation layer
>	 BASE_CFLAGS="-I/usr/include/mingw -mno-cygwin"
>	 BASE_LDFLAGS="-mno-cygwin"],
>	[*],
>	[BASE_CFLAGS="-D_GNU_SOURCE=1"
>         BASE_LDFLAGS=""])
>
>BUILD_CFLAGS="$CFLAGS $CPPFLAGS"
>EXTRA_CFLAGS="$INCLUDE $BASE_CFLAGS"
>BUILD_LDFLAGS="$LDFLAGS"
>EXTRA_LDFLAGS="$BASE_LDFLAGS"
>dnl These are common directories to find software packages
>dnl for path in /usr/freeware /usr/pkg /usr/X11R6 /usr/local; do
>dnl    if test -d $path/include; then
>dnl        EXTRA_CFLAGS="$EXTRA_CFLAGS -I$path/include"
>dnl    fi
>dnl    if test -d $path/lib; then
>dnl        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L$path/lib"
>dnl    fi
>dnl done
>SDL_CFLAGS="$BASE_CFLAGS"
>SDL_LIBS="-lSDL $BASE_LDFLAGS"
>CPPFLAGS="$CPPFLAGS $EXTRA_CFLAGS"
>CFLAGS="$CFLAGS $EXTRA_CFLAGS"
>LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
>
>dnl Check for compiler characteristics
>AC_C_CONST
>AC_C_INLINE
>AC_C_VOLATILE
>
>dnl AC_DEFUN([AC_CHECK_DEFINE],
>dnl 	 [AC_CACHE_CHECK([for $1 in $2, ac_cv_define_$1],
>dnl 			 [AC_EGREP_CPP([YES_IS_DEFINED], 
>dnl 				       [[#]include <$2>
>dnl 				        [#]ifdef $1
>dnl 					YES_IS_DEFINED
>dnl 					[#]endif],
>dnl 					[ac_cv_define_$1=yes],
>dnl 					[ac_cv_define_$1=no]) ])
>dnl 	 AS_IF([test "$ac_cv_define_$1" = "yes"],
>dnl 	       [AC_DEFINE([HAVE_$1]) ]) ])
>dnl 	 dnl AC_DEFINE([HAVE_$1]) ])
>
>dnl See whether we are allowed to use the system C library
>AC_ARG_ENABLE([libc],
>	      [AS_HELP_STRING([--enable-libc],
>			      [Use the system C library [[default=yes]] ]) ],
>	      [],
>	      [enable_libc=yes])
>
>AS_IF([test x$enable_libc = xyes],
>      [AC_DEFINE([HAVE_LIBC], 1,[Description])
>       dnl Check for C library headers
>       AC_HEADER_STDC
>       AC_CHECK_HEADERS(sys/types.h stdio.h stdlib.h stddef.h stdarg.h malloc.h memory.h string.h strings.h inttypes.h stdint.h ctype.h math.h iconv.h signal.h)
>       dnl Check for typedefs, structures, etc.
>       AC_TYPE_SIZE_T
>       AS_IF([test x$ac_cv_header_inttypes_h = xyes -o x$ac_cv_header_stdint_h = xyes],
>	     [AC_CHECK_TYPE([int64_t])
>	      AS_IF([test x$ac_cv_type_int64_t = xyes],
>		    [AC_DEFINE([SDL_HAS_64BIT_TYPE], 1,[Description]) ])
>	      have_inttypes=yes])
>
>       dnl Check for defines
>       AC_CHECK_DEFINE([M_PI], [math.h])
>
>       dnl Checks for library functions.
>       AS_CASE(["$host"],
>	       [*-*-cygwin* | *-*-mingw32*],
>	       [],
>	       [*],
>	       [AC_FUNC_ALLOCA])
>
>       AC_FUNC_MEMCMP
>       AS_IF([test x$ac_cv_func_memcmp_working = xyes],
>	     [AC_DEFINE([HAVE_MEMCMP], 1,[Description]) ])
>       AC_FUNC_STRTOD
>       AS_IF([test x$ac_cv_func_strtod = xyes],
>	     [AC_DEFINE([HAVE_STRTOD], 1,[Description]) ])
>       AC_CHECK_FUNCS(malloc calloc realloc free getenv putenv unsetenv qsort abs bcopy memset memcpy memmove strlen strlcpy strlcat strdup _strrev _strupr _strlwr strchr strrchr strstr itoa _ltoa _uitoa _ultoa strtol strtoul _i64toa _ui64toa strtoll strtoull atoi atof strcmp strncmp _stricmp strcasecmp _strnicmp strncasecmp sscanf snprintf vsnprintf sigaction setjmp nanosleep)
>
>       AC_CHECK_LIB([m],
>		    [pow], 
>		    [LIBS="$LIBS -lm"
>		     EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lm"])
>       AC_CHECK_FUNCS([ceil copysign cos cosf fabs floor log pow scalbn sin sinf sqrt])
>
>       AC_CHECK_LIB([iconv],
>		    [libiconv_open],
>		    [LIBS="$LIBS -liconv"
>		     EXTRA_LDFLAGS="$EXTRA_LDFLAGS -liconv"])
>       AC_CHECK_FUNCS([iconv]) ])
>
>AC_CHECK_SIZEOF([void*])
>AS_IF([test x$have_inttypes != xyes],
>      [AC_CHECK_SIZEOF([char], 1)
>       AC_CHECK_SIZEOF([short], 2)
>       AC_CHECK_SIZEOF([int], 4)
>       AC_CHECK_SIZEOF([long], 4)
>       AC_CHECK_SIZEOF([long long], 8)
>       AS_IF([test x$ac_cv_sizeof_char = x1],
>	     [AC_DEFINE([int8_t], [signed char], [Description])
>	      AC_DEFINE([uint8_t], [unsigned char], [Description]) ])
>       AS_IF([test x$ac_cv_sizeof_short = x2],
>	     [AC_DEFINE([int16_t], [signed short], [Description])
>	      AC_DEFINE([uint16_t], [unsigned short], [Description]) ],
>	     [AS_IF([test x$ac_cv_sizeof_int = x2],
>		    [AC_DEFINE([int16_t], [signed int], [Description])
>		     AC_DEFINE([uint16_t], [unsigned int], [Description]) ]) ])
>       AS_IF([test x$ac_cv_sizeof_int = x4],
>	     [AC_DEFINE([int32_t], [signed int], [Description])
>	      AC_DEFINE([uint32_t], [unsigned int], [Description]) ],
>	     [AS_IF([test x$ac_cv_sizeof_long = x4],
>		    [AC_DEFINE([int32_t], [signed long], [Description])
>		     AC_DEFINE([uint32_t], [unsigned long], [Description]) ]) ])
>      AS_IF([test x$ac_cv_sizeof_long = x8],
>	    [AC_DEFINE([int64_t], [signed long], [Description])
>	     AC_DEFINE([uint64_t], [unsigned long], [Description])
>	     AC_DEFINE([SDL_HAS_64BIT_TYPE], 1,[Description]) ],
>	    [AS_IF([test x$ac_cv_sizeof_long_long = x8],
>		   [AC_DEFINE([int64_t], [signed long long], [Description])
>		    AC_DEFINE([uint64_t], [unsigned long long], [Description])
>		    AC_DEFINE([SDL_HAS_64BIT_TYPE], 1,[Description]) ]) ])
>      AC_DEFINE([size_t], [unsigned int], [Description])
>      AC_DEFINE([uintptr_t], [unsigned long], [Description]) ])
>dnl end AS_IF([test x$have_inttypes != xyes] ...
>
>dnl Standard C sources
>dnl TODO: WTF does this do here?
>SOURCES="$SOURCES $srcdir/src/*.c"
>SOURCES="$SOURCES $srcdir/src/audio/*.c"
>SOURCES="$SOURCES $srcdir/src/cpuinfo/*.c"
>SOURCES="$SOURCES $srcdir/src/events/*.c"
>SOURCES="$SOURCES $srcdir/src/file/*.c"
>SOURCES="$SOURCES $srcdir/src/stdlib/*.c"
>SOURCES="$SOURCES $srcdir/src/thread/*.c"
>SOURCES="$SOURCES $srcdir/src/timer/*.c"
>SOURCES="$SOURCES $srcdir/src/video/*.c"
>
>dnl Enable/disable various subsystems of the SDL library
>
>AC_ARG_ENABLE([atomic],
>	      [AS_HELP_STRING([--enable-atomic],
>			      [Enable the atomic operations subsystem [[default=yes]] ]) ],
>              [],
>	      [enable_atomic=yes])
>AS_IF([test x$enable_atomic != xyes],
>      [AC_DEFINE([SDL_ATOMIC_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([audio],
>	      [AS_HELP_STRING([--enable-audio],
>			      [Enable the audio subsystem [[default=yes]] ]) ],
>	      [],
>              [enable_audio=yes])
>AS_IF([test x$enable_audio != xyes],
>      [AC_DEFINE([SDL_AUDIO_DISABLED], 1,[Description])])
>AC_ARG_ENABLE([video],
>	      [AS_HELP_STRING([--enable-video],
>			      [Enable the video subsystem [[default=yes]] ]) ],
>	      [],
>              [enable_video=yes])
>AS_IF([test x$enable_video != xyes],
>      [AC_DEFINE([SDL_VIDEO_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([events],
>	      [AS_HELP_STRING([--enable-events],
>			      [Enable the events subsystem [[default=yes]] ]) ],
>              [],
>              [enable_events=yes])
>AS_IF([test x$enable_events != xyes],
>      [AC_DEFINE([SDL_EVENTS_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([joystick],
>	      [AS_HELP_STRING([--enable-joystick],
>			      [Enable the joystick subsystem [[default=yes]] ]) ],
>	      [],
>              [enable_joystick=yes])
>AS_IF([test x$enable_joystick != xyes],
>      [AC_DEFINE([SDL_JOYSTICK_DISABLED], 1,[Description]) ],
>      [SOURCES="$SOURCES $srcdir/src/joystick/*.c"])
>AC_ARG_ENABLE([haptic],
>	      [AS_HELP_STRING([--enable-haptic],
>			      [Enable the haptic (force feedback) subsystem [[default=yes]] ]) ],
>	      [],
>              [enable_haptic=yes])
>AS_IF([test x$enable_haptic != xyes],
>      [AC_DEFINE([SDL_HAPTIC_DISABLED], 1,[Description]) ],
>      [SOURCES="$SOURCES $srcdir/src/haptic/*.c"])
>AC_ARG_ENABLE([power],
>	      [AS_HELP_STRING([--enable-power],
>			      [Enable the power subsystem [[default=yes]] ]) ],
>	      [],
>              [enable_power=yes])
>AS_IF([test x$enable_power != xyes],
>      [AC_DEFINE([SDL_POWER_DISABLED], 1,[Description]) ],
>      [SOURCES="$SOURCES $srcdir/src/power/*.c"])
>AC_ARG_ENABLE([threads],
>	      [AS_HELP_STRING([--enable-threads],
>			      [Enable the threading subsystem [[default=yes]] ]) ],
>	      [],
>	      [enable_threads=yes])
>AS_IF([test x$enable_threads != xyes],
>      [AC_DEFINE([SDL_THREADS_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([timers],
>	      [AS_HELP_STRING([--enable-timers],
>			      [Enable the timer subsystem [[default=yes]] ]) ],
>	      [],
>	      [enable_timers=yes])
>AS_IF([test x$enable_timers != xyes],
>      [AC_DEFINE([SDL_TIMERS_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([file],
>	      [AS_HELP_STRING([--enable-file],
>			      [Enable the file subsystem [[default=yes]] ]) ],
>	      [],
>	      [enable_file=yes])
>AS_IF([test x$enable_file != xyes],
>      [AC_DEFINE([SDL_FILE_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([loadso],
>	      [AS_HELP_STRING([--enable-loadso],
>			      [Enable the shared object loading subsystem [[default=yes]] ]) ],
>	      [],
>	      [enable_loadso=yes])
>AS_IF([test x$enable_loadso != xyes],
>      [AC_DEFINE([SDL_LOADSO_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([cpuinfo],
>	      [AS_HELP_STRING([--enable-cpuinfo],
>			      [Enable the cpuinfo subsystem [[default=yes]] ]) ],
>	      [],
>	      [enable_cpuinfo=yes])
>AS_IF([test x$enable_cpuinfo != xyes],
>      [AC_DEFINE([SDL_CPUINFO_DISABLED], 1,[Description]) ])
>AC_ARG_ENABLE([assembly],
>	      [AS_HELP_STRING([--enable-assembly],
>			      [Enable assembly routines [[default=yes]] ]) ],
>	      [],
>	      [enable_assembly=yes])
>
>AS_IF([test x$enable_assembly = xyes],
>      [AC_DEFINE([SDL_ASSEMBLY_ROUTINES], 1,[Description])
>       dnl Make sure that we don't generate floating point code that would
>       dnl illegal instruction exceptions on older processors
>       AS_CASE(["$host"],
>	       [*-*-darwin*],
>	       [dnl Don't need to worry about Apple hardware, it's all SSE capable
>		default_ssemath=yes],
>	       [*64-*-*],
>	       [dnl x86 64-bit architectures all have SSE instructions
>		default_ssemath=yes],
>	       [*],
>	       [default_ssemath=no])
>       AC_ARG_ENABLE([ssemath],
>		     [AS_HELP_STRING([--enable-ssemath],
>				     [Allow GCC to use SSE floating point math [[default=no]] ]) ],
>		     [],
>		     [enable_ssemath=$default_ssemath])
>       AS_IF([test x$enable_ssemath = xno],
>	     [AS_IF([test x$have_gcc_sse = xyes -o x$have_gcc_sse2 = xyes],
>		    [EXTRA_CFLAGS="$EXTRA_CFLAGS -mfpmath=387"]) ])
>       dnl Check for various instruction support
>       AC_ARG_ENABLE([mmx],
>		     [AS_HELP_STRING([--enable-mmx],
>				     [use MMX assembly routines [[default=yes]] ]) ],
>		     [],
>		     [enable_mmx=yes])
>       AS_IF([test x$enable_mmx = xyes],
>	     [save_CFLAGS="$CFLAGS"
>	      have_gcc_mmx=no
>	      AC_MSG_CHECKING(for GCC -mmmx option)
>	      mmx_CFLAGS="-mmmx"
>	      CFLAGS="$save_CFLAGS $mmx_CFLAGS"
>	      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <mmintrin.h>
>						   #ifndef __MMX__
>						   #error Assembler CPP flag not enabled
>						   #endif]], 
>						   [] )],
>			        [have_gcc_mmx=yes],
>				[])
>	      AC_MSG_RESULT([$have_gcc_mmx])
>	      CFLAGS="$save_CFLAGS"
>	      AS_IF([test x$have_gcc_mmx = xyes],
>		    [EXTRA_CFLAGS="$EXTRA_CFLAGS $mmx_CFLAGS"]) ])
>
>	  AC_ARG_ENABLE([3dnow],
>			[AS_HELP_STRING([--enable-3dnow],
>					[use MMX assembly routines [[default=yes]] ]) ],
>			[],
>			[enable_3dnow=yes])
>	  AS_IF([test x$enable_3dnow = xyes],
>		[save_CFLAGS="$CFLAGS"
>		 have_gcc_3dnow=no
>		 AC_MSG_CHECKING([for GCC -m3dnow option])
>		 amd3dnow_CFLAGS="-m3dnow"
>		 CFLAGS="$save_CFLAGS $amd3dnow_CFLAGS"
>
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <mm3dnow.h>
>						      #ifndef __3dNOW__
>						      #error Assembler CPP flag not enabled
>						      #endif]],
>						    []) ],
>				   [have_gcc_3dnow=yes],
>				   [])
>		 AC_MSG_RESULT([$have_gcc_3dnow])
>		 CFLAGS="$save_CFLAGS"
>		 AS_IF([test x$have_gcc_3dnow = xyes],
>		       [EXTRA_CFLAGS="$EXTRA_CFLAGS $amd3dnow_CFLAGS"]) ])
>
>      AC_ARG_ENABLE([sse],
>		    [AS_HELP_STRING([--enable-sse],[use SSE assembly routines [[default=yes]] ]) ],
>		    [],
>                    [enable_sse=yes])
>      AS_IF([test x$enable_sse = xyes],
>	    [save_CFLAGS="$CFLAGS"
>	     have_gcc_sse=no
>	     AC_MSG_CHECKING([for GCC -msse option])
>	     sse_CFLAGS="-msse"
>	     CFLAGS="$save_CFLAGS $sse_CFLAGS"
>	     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <xmmintrin.h>
>						  #ifndef __SSE__
>						  #error Assembler CPP flag not enabled
>						  #endif]],
>						[]) ],
>			      [have_gcc_sse=yes],
>			      [])
>	     AC_MSG_RESULT([$have_gcc_sse])
>	     CFLAGS="$save_CFLAGS"
>
>	     AS_IF([test x$have_gcc_sse = xyes],
>		   [EXTRA_CFLAGS="$EXTRA_CFLAGS $sse_CFLAGS"]) ])
>
>      AC_ARG_ENABLE([sse2],
>		    [AS_HELP_STRING([--enable-sse2],
>				    [use SSE2 assembly routines [[default=no]] ]) ],
>		    [],
>		    [enable_sse2=$default_ssemath])
>      AS_IF([test x$enable_sse2 = xyes],
>	    [save_CFLAGS="$CFLAGS"
>	     have_gcc_sse2=no
>	     AC_MSG_CHECKING([for GCC -msse2 option])
>	     sse2_CFLAGS="-msse2"
>	     CFLAGS="$save_CFLAGS $sse2_CFLAGS"
>	     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <emmintrin.h>
>						  #ifndef __SSE2__
>						  #error Assembler CPP flag not enabled
>						  #endif]],
>						[]) ],
>			       [have_gcc_sse2=yes],
>			       [])
>	     AC_MSG_RESULT([$have_gcc_sse2])
>	     CFLAGS="$save_CFLAGS"
>	     AS_IF([test x$have_gcc_sse2 = xyes],
>		   [EXTRA_CFLAGS="$EXTRA_CFLAGS $sse2_CFLAGS"]) ])
>
>      AC_ARG_ENABLE([altivec],
>		    [AS_HELP_STRING([--enable-altivec],
>				    [use Altivec assembly routines [[default=yes]] ]) ],
>		    [],
>		    [enable_altivec=yes])
>      AS_IF([test x$enable_altivec = xyes],
>	    [have_altivec_h_hdr=no
>	     AC_CHECK_HEADER(altivec.h, have_altivec_h_hdr=yes)
>	     save_CFLAGS="$CFLAGS"
>	     have_gcc_altivec=no
>	     AC_MSG_CHECKING([for Altivec with GCC -maltivec option])
>	     altivec_CFLAGS="-maltivec"
>	     CFLAGS="$save_CFLAGS $altivec_CFLAGS"
>	     AS_IF([test x$have_altivec_h_hdr = xyes],
>		   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <altivec.h>
>							 vector unsigned int vzero()
>							 { return vec_splat_u32(0); }]], 
>						       []) ],
>				      [have_gcc_altivec=yes],
>				      [])
>		    AC_MSG_RESULT([$have_gcc_altivec])],
>		   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[vector unsigned int vzero()
>							 { return vec_splat_u32(0); }]],
>						       []) ],
>				      [have_gcc_altivec=yes],
>				      [])
>		    AC_MSG_RESULT($have_gcc_altivec) ])
>
>             AS_IF([test x$have_gcc_altivec = xno],
>		   [AC_MSG_CHECKING([for Altivec with GCC -faltivec option])
>		    altivec_CFLAGS="-faltivec"
>		    CFLAGS="$save_CFLAGS $altivec_CFLAGS"
>		    AS_IF([test x$have_altivec_h_hdr = xyes],
>			  [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <altivec.h>
>								vector unsigned int vzero()
>								{ return vec_splat_u32(0); }]],
>							      []) ],
>					     [have_gcc_altivec=yes],
>					     [])
>			  AC_MSG_RESULT([$have_gcc_altivec]) ],
>			 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[vector unsigned int vzero()
>							       { return vec_splat_u32(0); }]],
>							     []) ],
>					    [have_gcc_altivec=yes],
>					    [])
>			  AC_MSG_RESULT([$have_gcc_altivec]) ]) ])
>	     CFLAGS="$save_CFLAGS"
>	     AS_IF([test x$have_gcc_altivec = xyes],
>		   [AC_DEFINE([SDL_ALTIVEC_BLITTERS], 1,[Description])
>		    AS_IF([test x$have_altivec_h_hdr = xyes],
>			  [AC_DEFINE([HAVE_ALTIVEC_H], 1,[Description]) ])
>		    EXTRA_CFLAGS="$EXTRA_CFLAGS $altivec_CFLAGS"]) ]) ])
>
>dnl TODO: What is this...
>dnl set this to use on systems that use lib64 instead of lib
>base_libdir=`echo \${libdir} | sed 's/.*\/$.*$/\1/; q'`
>
>dnl See if the OSS audio interface is supported
>AC_DEFUN([CHECK_OSS],
>	 [AC_ARG_ENABLE([oss],
>			[AS_HELP_STRING([--enable-oss],
>					[support the OSS audio API [[default=yes]] ]) ],
>			[],
>			[enable_oss=yes])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_oss = xyes],
>	       [AC_MSG_CHECKING(for OSS audio support)
>	        have_oss=no
>	        AS_IF([test x$have_oss != xyes],
>		      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/soundcard.h>]], 
>							  [[int arg = SNDCTL_DSP_SETFRAGMENT;]]) ],
>					 [have_oss=yes],
>					 []) ])
>		AS_IF([test x$have_oss != xyes],
>		      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <soundcard.h>]], 
>							  [[int arg = SNDCTL_DSP_SETFRAGMENT;]]) ],
>					 [have_oss=yes
>					  AC_DEFINE([SDL_AUDIO_DRIVER_OSS_SOUNDCARD_H], 1,[Description])],
>					 []) ])
>		AC_MSG_RESULT($have_oss)
>		AS_IF([test x$have_oss = xyes],
>		      [AC_DEFINE([SDL_AUDIO_DRIVER_OSS], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/audio/dsp/*.c"
>		       SOURCES="$SOURCES $srcdir/src/audio/dma/*.c"
>		       have_audio=yes
>		       dnl We may need to link with ossaudio emulation library
>		       AS_CASE(["$host"],
>			       [*-*-openbsd*|*-*-netbsd*],
>			       [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lossaudio"]) ]) ]) ])
>
>dnl See if the ALSA audio interface is supported
>AC_DEFUN([CHECK_ALSA],
>	 [AC_ARG_ENABLE([alsa],[AS_HELP_STRING([--enable-alsa],
>					       [support the ALSA audio API [[default=yes]] ]) ],
>			[],
>			[enable_alsa=yes])
>	  AS_IF([test x$enable_audio = xyes -a x$enable_alsa = xyes],
>		[AM_PATH_ALSA(0.9.0, [have_alsa=yes], [have_alsa=no])
>		 dnl Restore all flags from before the ALSA detection runs
>		 CFLAGS="$alsa_save_CFLAGS"
>		 LDFLAGS="$alsa_save_LDFLAGS"
>		 LIBS="$alsa_save_LIBS"
>		 AS_IF([test x$have_alsa = xyes],
>		       [AC_ARG_ENABLE(alsa-shared,
>		       [AS_HELP_STRING([--enable-alsa-shared],
>				       [dynamically load ALSA audio support [[default=yes]] ]) ],
>		       [],
>		       [enable_alsa_shared=yes])
>		 AS_IF([test "x`echo $ALSA_LIBS | grep -- -L`" = "x"],
>		       [AS_IF([test "x`ls /$base_libdir/libasound.so.* 2> /dev/null`" != "x"],
>			      [ALSA_LIBS="-L/$base_libdir $ALSA_LIBS"],
>			      [test "x`ls /usr/$base_libdir/libasound.so.* 2> /dev/null`" != "x"],
>			      [ALSA_LIBS="-L/usr/$base_libdir $ALSA_LIBS"],
>			      [test "x`ls /usr/local/$base_libdir/libasound.so.* 2> /dev/null`" != "x"],
>			      [ALSA_LIBS="-L/usr/local/$base_libdir $ALSA_LIBS"]) ])
>		 alsa_lib_spec=`echo $ALSA_LIBS | sed 's/.*-L$[[^ ]]*$.*/\1\/libasound.so.*/'`
>		 AS_IF([test x$alsa_lib_spec = x],
>		       [alsa_lib_spec="/usr/$base_libdir/libasound.so.*"])
>		 alsa_lib=`ls -- $alsa_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		 echo "-- $alsa_lib_spec -> $alsa_lib"
>
>		 AC_DEFINE([SDL_AUDIO_DRIVER_ALSA], 1,[Description])
>		 SOURCES="$SOURCES $srcdir/src/audio/alsa/*.c"
>		 EXTRA_CFLAGS="$EXTRA_CFLAGS $ALSA_CFLAGS"
>		 AS_IF([test x$have_loadso != xyes -a x$enable_alsa_shared = xyes],
>		       [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic ALSA loading]) ])
>		 AS_IF([test x$have_loadso = xyes -a x$enable_alsa_shared = xyes -a x$alsa_lib != x],
>		       [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_ALSA_DYNAMIC], 
>					   ["$alsa_lib"],
>					   [Description]) ],
>		       [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $ALSA_LIBS"])
>		 have_audio=yes]) ]) ])
>
>dnl Check whether we want to use IRIX 6.5+ native audio or not
>AC_DEFUN([CHECK_DMEDIA],
>	 [AS_IF([test x$enable_audio = xyes],
>		[AC_MSG_CHECKING([for dmedia audio support])
>		 have_dmedia=no
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <dmedia/audio.h>]],
>						    [[ALport audio_port;]]) ],
>				   [have_dmedia=yes],
>				   [])
>		 AC_MSG_RESULT([$have_dmedia])
>		 dnl Set up files for the audio library
>		 AS_IF([test x$have_dmedia = xyes],
>		       [AC_DEFINE([SDL_AUDIO_DRIVER_DMEDIA], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/audio/dmedia/*.c"
>		        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -laudio"
>		        have_audio=yes]) ]) ])
>
>dnl Check whether we want to use Tru64 UNIX native audio or not
>AC_DEFUN([CHECK_MME],
>	 [dnl Make sure we are running on an Tru64 UNIX
>	  AS_CASE([$ARCH],
>		  [osf],
>		  [mme_platform="yes"],
>		  [*],
>		  [mme_platform="no"])
>	  AS_IF([test x$enable_audio = xyes -a x$mme_platform = xyes],
>		[AC_MSG_CHECKING([for MME audio support])
>		 MME_CFLAGS="-I/usr/include/mme"
>		 MME_LIBS="-lmme"
>		 have_mme=no
>		 save_CFLAGS="$CFLAGS"
>		 CFLAGS="$CFLAGS $MME_CFLAGS"
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <mme_api.h>]],
>						    [[HWAVEOUT sound;]]) ],
>				   [have_mme=yes],
>				   [])
>		 CFLAGS="$save_CFLAGS"
>		 AC_MSG_RESULT([$have_mme])
>		 dnl Set up files for the audio library
>		 AS_IF([test x$have_mme = xyes],
>		       [AC_DEFINE([SDL_AUDIO_DRIVER_MMEAUDIO], 1,[Description])
>		 SOURCES="$SOURCES $srcdir/src/audio/mme/*.c"
>		 EXTRA_CFLAGS="$EXTRA_CFLAGS $MME_CFLAGS"
>		 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $MME_LIBS"
>		 have_audio=yes]) ]) ])
>
>dnl Find the ESD includes and libraries
>AC_DEFUN([CHECK_ESD],
>	 [AC_ARG_ENABLE([esd],[AS_HELP_STRING([--enable-esd],
>					      [support the Enlightened Sound Daemon [[default=yes]] ]) ],
>			[],
>			[enable_esd=yes])
>	  AS_IF([test x$enable_audio = xyes -a x$enable_esd = xyes],
>		[AM_PATH_ESD(0.2.8, [have_esd=yes], [have_esd=no])
>		 AS_IF([test x$have_esd = xyes],
>		       [AC_ARG_ENABLE([esd-shared],
>				      [AS_HELP_STRING([--enable-esd-shared],
>						      [dynamically load ESD audio support [[default=yes]] ]) ],
>				      [],
>				      [enable_esd_shared=yes])
>		        esd_lib_spec=`echo $ESD_LIBS | sed 's/.*-L$[[^ ]]*$.*/\1\/libesd.so.*/'`
>			AS_IF([test x$esd_lib_spec = x],
>			      [esd_lib_spec="/usr/$base_libdir/libesd.so.*"])
>		        esd_lib=`ls -- $esd_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		        echo "-- $esd_lib_spec -> $esd_lib"
>
>		        AC_DEFINE([SDL_AUDIO_DRIVER_ESD], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/audio/esd/*.c"
>		        EXTRA_CFLAGS="$EXTRA_CFLAGS $ESD_CFLAGS"
>		        AS_IF([test x$have_loadso != xyes -a x$enable_esd_shared = xyes],
>			      [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic ESD loading]) ])
>			AS_IF([test x$have_loadso = xyes -a x$enable_esd_shared = xyes -a x$esd_lib != x],
>			      [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_ESD_DYNAMIC], ["$esd_lib"], [Description])],
>			      [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $ESD_LIBS"])
>			have_audio=yes]) ]) ])
>
>dnl Find PulseAudio
>AC_DEFUN([CHECK_PULSEAUDIO],
>	 [AC_ARG_ENABLE([pulseaudio],
>			[AS_HELP_STRING([--enable-pulseaudio],
>					[use PulseAudio [[default=yes]] ]) ],
>			[],
>			[enable_pulseaudio=yes])
>	 dnl TODO: We check for pkg-config here. Bad place for doing so...
>	 AS_IF([test x$enable_audio = xyes -a x$enable_pulseaudio = xyes],
>	       [audio_pulseaudio=no
>	        PULSEAUDIO_REQUIRED_VERSION=0.9
>	        AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
>		dnl TODO: Fix pkg-config calls
>	        AC_MSG_CHECKING(for PulseAudio $PULSEAUDIO_REQUIRED_VERSION support)
>	        AS_IF([test x$PKG_CONFIG != xno],
>		      [AS_IF([$PKG_CONFIG --atleast-pkgconfig-version 0.7 && $PKG_CONFIG --atleast-version $PULSEAUDIO_REQUIRED_VERSION libpulse-simple],
>			     [PULSEAUDIO_CFLAGS=`$PKG_CONFIG --cflags libpulse-simple`
>			      PULSEAUDIO_LIBS=`$PKG_CONFIG --libs libpulse-simple`
>			      audio_pulseaudio=yes]) ])
>		AC_MSG_RESULT([$audio_pulseaudio])
>		AS_IF([test x$audio_pulseaudio = xyes],
>		      [AC_ARG_ENABLE([pulseaudio-shared],
>				     [AS_HELP_STRING([--enable-pulseaudio-shared],
>						     [dynamically load PulseAudio support [[default=yes]] ]) ],
>				     [],
>				     [enable_pulseaudio_shared=yes])
>		       AS_IF([test "x`echo $PULSEAUDIO_LIBS | grep -- -L`" = "x"],
>			     [AS_IF([test "x`ls /$base_libdir/libpulse-simple.so.* 2> /dev/null`" != "x"],
>				    [PULSE_LIBS="-L/$base_libdir $PULSE_LIBS"],
>				    [test "x`ls /usr/$base_libdir/libpulse-simple.so.* 2> /dev/null`" != "x"],
>				    [PULSE_LIBS="-L/usr/$base_libdir $PULSE_LIBS"],
>				    [test "x`ls /usr/local/$base_libdir/libpulse-simple.so.* 2> /dev/null`" != "x"],
>				    [PULSE_LIBS="-L/usr/local/$base_libdir $PULSE_LIBS"]) ])
>		       pulseaudio_lib_spec=`echo $PULSEAUDIO_LIBS | sed 's/.*-L$[[^ ]]*$.*/\1\/libpulse-simple.so.*/'`
>			AS_IF([test x$pulseaudio_lib_spec = x],
>			      [pulseaudio_lib_spec="/usr/$base_libdir/libpulse-simple.so.*"])
>		       pulseaudio_lib=`ls -- $pulseaudio_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		       echo "-- $pulseaudio_lib_spec -> $pulseaudio_lib"
>		       AC_DEFINE([SDL_AUDIO_DRIVER_PULSEAUDIO], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/audio/pulseaudio/*.c"
>		       EXTRA_CFLAGS="$EXTRA_CFLAGS $PULSEAUDIO_CFLAGS"
>		       AS_IF([test x$have_loadso != xyes -a x$enable_pulseaudio_shared = xyes],
>			     [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic PulseAudio loading]) ])
>		       AS_IF([test x$have_loadso = xyes -a x$enable_pulseaudio_shared = xyes -a x$pulseaudio_lib != x],
>			     [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_PULSEAUDIO_DYNAMIC], ["$pulseaudio_lib"], [Description]) ],
>			     [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $PULSEAUDIO_LIBS"])
>		       have_audio=yes]) ]) ])
>
>AC_DEFUN([CHECK_ARTS],
>	 [AC_ARG_ENABLE([arts],
>			[AS_HELP_STRING([--enable-arts],
>					[support the Analog Real Time Synthesizer [[default=yes]] ]) ],
>			[],
>			[enable_arts=yes])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_arts = xyes],
>	       [AC_PATH_PROG([ARTSCONFIG], [artsc-config])
>	       AS_IF([test x$ARTSCONFIG = x -o x$ARTSCONFIG = x'"$ARTSCONFIG"'],
>		     [[: # arts isn't installed]],
>		     [ARTS_CFLAGS=`$ARTSCONFIG --cflags`
>		      ARTS_LIBS=`$ARTSCONFIG --libs`
>		      ARTS_PREFIX=`$ARTSCONFIG --arts-prefix`
>		      AC_MSG_CHECKING([for aRts development environment])
>		      audio_arts=no
>		      save_CFLAGS="$CFLAGS"
>		      CFLAGS="$CFLAGS $ARTS_CFLAGS"
>		      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <artsc.h>]],
>							 [[arts_stream_t stream;]]) ],
>					[audio_arts=yes],
>					[])
>		      CFLAGS="$save_CFLAGS"
>		      AC_MSG_RESULT([$audio_arts])
>		      AS_IF([test x$audio_arts = xyes],
>			    [AC_ARG_ENABLE([arts-shared],
>					   [AS_HELP_STRING([--enable-arts-shared],
>							   [dynamically load aRts audio support [[default=yes]] ]) ],
>					   [],
>					   [enable_arts_shared=yes])
>		      arts_lib_spec="$ARTS_PREFIX/$base_libdir/libartsc.so.*"
>		      arts_lib=`ls -- $arts_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		      echo "-- $arts_lib_spec -> $arts_lib"
>
>		      AC_DEFINE([SDL_AUDIO_DRIVER_ARTS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/audio/arts/*.c"
>		      EXTRA_CFLAGS="$EXTRA_CFLAGS $ARTS_CFLAGS"
>		      AS_IF([test x$have_loadso != xyes -a x$enable_arts_shared = xyes],
>			    [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic ARTS loading]) ])
>		      AS_IF([test x$have_loadso = xyes -a x$enable_arts_shared = xyes -a  x$arts_lib != x],
>			    [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_ARTS_DYNAMIC], "$arts_lib", [Description]) ],
>			    [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $ARTS_LIBS"])
>		      have_audio=yes]) ]) ]) ])
>
>dnl See if the NAS audio interface is supported
>AC_DEFUN([CHECK_NAS],
>	 [AC_ARG_ENABLE([nas],
>			[AS_HELP_STRING([--enable-nas],
>					[support the NAS audio API [[default=yes]] ]) ],
>			[],
>			[enable_nas=yes])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_nas = xyes],
>	       [AC_CHECK_HEADER([audio/audiolib.h], [have_nas_hdr=yes])
>	        AC_CHECK_LIB(audio, AuOpenServer, have_nas_lib=yes)
>	        AC_MSG_CHECKING([for NAS audio support])
>	        have_nas=no
>	        AS_IF([test x$have_nas_hdr = xyes -a x$have_nas_lib = xyes],
>		      [have_nas=yes
>		       NAS_LIBS="-laudio"],
>		      [test -r /usr/X11R6/include/audio/audiolib.h],
>		      [have_nas=yes
>		       NAS_CFLAGS="-I/usr/X11R6/include/"
>		       NAS_LIBS="-L/usr/X11R6/lib -laudio -lXt"],
>		       dnl On IRIX, the NAS includes are in a different directory,
>		       dnl and libnas must be explicitly linked in
>		      [test -r /usr/freeware/include/nas/audiolib.h],
>		      [have_nas=yes
>		       NAS_LIBS="-lnas -lXt"])
>		AC_MSG_RESULT($have_nas)
>		AS_IF([test x$have_nas = xyes],
>		      [AC_ARG_ENABLE([nas-shared],
>				     [AS_HELP_STRING([--enable-nas-shared],
>						     [dynamically load NAS audio support [[default=yes]] ]) ],
>				     [],
>				     [enable_nas_shared=yes])
>		AS_IF([test "x`echo $NAS_LIBS | grep -- -L`" = "x"],
>		      [AS_IF([test "x`ls /lib/libaudio.so.* 2> /dev/null`" != "x"],
>			     [NAS_LIBS="-L/lib $NAS_LIBS"],
>			     [test "x`ls /usr/lib/libaudio.so.* 2> /dev/null`" != "x"],
>			     [NAS_LIBS="-L/usr/lib $NAS_LIBS"],
>			     [test "x`ls /usr/local/lib/libaudio.so.* 2> /dev/null`" != "x"],
>			     [NAS_LIBS="-L/usr/local/lib $NAS_LIBS"]) ])
>		nas_lib_spec=`echo $NAS_LIBS | sed 's/.*-L$[[^ ]]*$.*/\1\/libaudio.so.*/'`
>		AS_IF([test x$nas_lib_spec = x],
>		      [nas_lib_spec="/usr/$base_libdir/libaudio.so.*"])
>		nas_lib=`ls -- $nas_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		echo "-- $nas_lib_spec -> $nas_lib"
>		AS_IF([test x$have_loadso != xyes -a x$enable_nas_shared = xyes],
>		      [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic NAS loading]) ])
>		AS_IF([test x$have_loadso = xyes -a x$enable_nas_shared = xyes -a x$nas_lib != x],
>		      [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_NAS_DYNAMIC], ["$nas_lib"], [Description]) ],
>		      [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $NAS_LIBS"])
>		AC_DEFINE([SDL_AUDIO_DRIVER_NAS], 1,[Description])
>		SOURCES="$SOURCES $srcdir/src/audio/nas/*.c"
>		EXTRA_CFLAGS="$EXTRA_CFLAGS $NAS_CFLAGS"
>		have_audio=yes]) ]) ])
>
>dnl rcg07142001 See if the user wants the disk writer audio driver...
>AC_DEFUN([CHECK_DISC_AUDIO],
>	 [AC_ARG_ENABLE([diskaudio],
>			[AS_HELP_STRING([--enable-diskaudio],
>					[support the disk writer audio driver [[default=yes]] ]) ],
>			[],
>			[enable_diskaudio=yes])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_diskaudio = xyes],
>	       [AC_DEFINE([SDL_AUDIO_DRIVER_DISK], 1,[Description])
>	        SOURCES="$SOURCES $srcdir/src/audio/disk/*.c"]) ])
>
>dnl rcg03142006 See if the user wants the dummy audio driver...
>AC_DEFUN([CHECK_DUMMY_AUDIO],
>	 [AC_ARG_ENABLE([dummyaudio],
>			[AS_HELP_STRING([--enable-dummyaudio],
>					[support the dummy audio driver [[default=yes]] ]) ],
>			[],
>			[enable_dummyaudio=yes])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_dummyaudio = xyes],
>	       [AC_DEFINE([SDL_AUDIO_DRIVER_DUMMY], 1,[Description])
>	        SOURCES="$SOURCES $srcdir/src/audio/dummy/*.c"]) ])
>
>dnl See if GCC's -fvisibility=hidden is supported (gcc4 and later, usually).
>dnl  Details of this flag are here: http://gcc.gnu.org/wiki/Visibility
>AC_DEFUN([CHECK_VISIBILITY_HIDDEN],
>	 [AC_MSG_CHECKING([for GCC -fvisibility=hidden option])
>	  have_gcc_fvisibility=no
>
>	  visibility_CFLAGS="-fvisibility=hidden"
>	  save_CFLAGS="$CFLAGS"
>	  CFLAGS="$save_CFLAGS $visibility_CFLAGS -Werror"
>	  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if !defined(__GNUC__) || __GNUC__ < 4
>					       #error SDL only uses visibility attributes in GCC 4 or newer
>					       #endif]],
>					     []) ],
>			    [have_gcc_fvisibility=yes],
>			    [])
>	  AC_MSG_RESULT([$have_gcc_fvisibility])
>	  CFLAGS="$save_CFLAGS"
>	  AS_IF([test x$have_gcc_fvisibility = xyes],
>		[EXTRA_CFLAGS="$EXTRA_CFLAGS $visibility_CFLAGS"]) ])
>
>dnl Find the X11 include and library directories
>AC_DEFUN([CHECK_X11],
>	 [AC_ARG_ENABLE([video-x11],
>			[AS_HELP_STRING([--enable-video-x11],
>					[use X11 video driver [[default=yes]] ]) ],
>			[],
>			[enable_video_x11=yes])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_x11 = xyes],
>	       [AS_CASE(["$host"],
>			[*-*-darwin*],
>			[dnl This isn't necessary for X11, but fixes GLX detection
>			 AS_IF([test "x$x_includes" = xNONE -a "x$x_libraries" = xNONE],
>			       [x_includes="/usr/X11R6/include"
>				x_libraries="/usr/X11R6/lib"]) ])
>	       AC_PATH_X
>	       AC_PATH_XTRA
>	       AS_IF([test x$have_x = xyes],
>		     [dnl Only allow dynamically loaded X11 if the X11 function pointers
>		      dnl will not end up in the global namespace, which causes problems
>		      dnl with other libraries calling X11 functions.
>		      x11_symbols_private=$have_gcc_fvisibility
>		      AC_ARG_ENABLE([x11-shared],
>				    [AS_HELP_STRING([--enable-x11-shared],
>						    [dynamically load X11 support [[default=maybe]] ]) ],
>				    [],
>				    [enable_x11_shared=maybe])
>		      AS_CASE(["$host"],
>			      [*-*-darwin*], dnl Latest Mac OS X actually ships with Xrandr/Xrender libs...
>			      [x11_symbols_private=yes dnl TODO: Does this really have to bee here
>			       x11_lib='/usr/X11R6/lib/libX11.6.dylib'
>			       x11ext_lib='/usr/X11R6/lib/libXext.6.dylib'
>			       xrender_lib='/usr/X11R6/lib/libXrender.1.dylib'
>			       xrandr_lib='/usr/X11R6/lib/libXrandr.2.dylib'
>			       xinput_lib='/usr/X11R6/lib/libXi.6.dylib'
>			       xss_lib='/usr/X11R6/lib/libXss.6.dylib'],
>			      [*-*-osf*],
>			      [x11_lib='libX11.so'
>			       x11ext_lib='libXext.so'],
>			      [*-*-irix*], dnl IRIX 6.5 requires that we use /usr/lib32
>			      [x11_lib='libX11.so'
>			       x11ext_lib='libXext.so'],
>			      [*],
>			      [x11_lib_spec=[`echo $X_LIBS | sed 's/.*-L$[^ ]*$.*/\1/'`]
>			       for path in $x11_lib_path /usr/$base_libdir /usr/X11/$base_libdir /usr/X11R6/$base_libdir; do
>			       AS_IF([test "x$x11_lib" = "x"],
>				     [x11_lib=[`ls -- $path/libX11.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				      AS_IF([test "x$x11_lib" = "x"],
>					    [x11_lib=[`ls -- $path/libX11.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      AS_IF([test "x$x11ext_lib" = "x"],
>				    [x11ext_lib=[`ls -- $path/libXext.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				     AS_IF([test "x$x11ext_lib" = "x"],
>					   [x11ext_lib=[`ls -- $path/libXext.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      AS_IF([test "x$xrender_lib" = "x"],
>				    [xrender_lib=[`ls -- $path/libXrender.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				     AS_IF([test "x$xrender_lib" = "x"],
>					   [xrender_lib=[`ls -- $path/libXrender.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      AS_IF([test "x$xrandr_lib" = "x"],
>				    [xrandr_lib=[`ls -- $path/libXrandr.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				     AS_IF([test "x$xrandr_lib" = "x"],
>					   [xrandr_lib=[`ls -- $path/libXrandr.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      AS_IF([test "x$xinput_lib" = "x"],
>				    [xinput_lib=[`ls -- $path/libXi.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				     AS_IF([test "x$xinput_lib" = "x"],
>					   [xinput_lib=[`ls -- $path/libXi.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      AS_IF([test "x$xss_lib" = "x"],
>				    [xss_lib=[`ls -- $path/libXss.so.[0-9] 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`]
>				     AS_IF([test "x$xss_lib" = "x"],
>					   [xss_lib=[`ls -- $path/libXss.so.[0-9]* 2>/dev/null | sort -r | sed 's/.*\/$.*$/\1/; q'`] ]) ])
>			      done ])
>		      AS_IF([test x$ac_cv_func_shmat != xyes],
>			    [X_CFLAGS="$X_CFLAGS -DNO_SHARED_MEMORY"])
>		      CFLAGS="$CFLAGS $X_CFLAGS"
>		      LDFLAGS="$LDFLAGS $X_LIBS"
>
>		      AC_DEFINE([SDL_VIDEO_DRIVER_X11], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/video/x11/*.c"
>		      SOURCES="$SOURCES $srcdir/src/video/Xext/XmuStdCmap/*.c"
>		      EXTRA_CFLAGS="$EXTRA_CFLAGS $X_CFLAGS"
>
>		      AS_IF([test x$enable_x11_shared = xmaybe],
>			    [enable_x11_shared=$x11_symbols_private])
>		      AS_IF([test x$have_loadso != xyes -a x$enable_x11_shared = xyes],
>			    [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic X11 loading])
>			     enable_x11_shared=no])
>		      AS_IF([test x$x11_symbols_private != xyes -a x$enable_x11_shared = xyes],
>			    [AC_MSG_WARN([You must have gcc4 (-fvisibility=hidden) for dynamic X11 loading])
>			     enable_x11_shared=no])
>		      AS_IF([test x$have_loadso = xyes -a x$enable_x11_shared = xyes -a x$x11_lib != x -a x$x11ext_lib != x],
>			    [echo "-- dynamic libX11 -> $x11_lib"
>			     echo "-- dynamic libX11ext -> $x11ext_lib"
>			     AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC], ["$x11_lib"], [Description])
>			     AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC_XEXT], ["$x11ext_lib"], [Description]) ],
>			    [enable_x11_shared=no
>			     EXTRA_LDFLAGS="$EXTRA_LDFLAGS $X_LIBS -lX11 -lXext"])
>		      have_video=yes
>		      AC_ARG_ENABLE([video-x11-vm],
>				    [AS_HELP_STRING([--enable-video-x11-vm],
>						    [use X11 VM extension for fullscreen [[default=yes]] ]) ],
>				    [],
>				    [enable_video_x11_vm=yes])
>		      AS_IF([test x$enable_video_x11_vm = xyes],
>			    [AC_DEFINE([SDL_VIDEO_DRIVER_X11_VIDMODE], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/video/Xext/Xxf86vm/*.c"])
>		      AC_ARG_ENABLE([video-x11-xv],
>				    [AS_HELP_STRING([--enable-video-x11-xv],
>						    [use X11 XvImage extension for video [[default=yes]] ]) ],
>				    [],
>				    [enable_video_x11_xv=yes])
>		      AS_IF([test x$enable_video_x11_xv = xyes],
>			    [AC_DEFINE([SDL_VIDEO_DRIVER_X11_XV], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/video/Xext/Xv/*.c"])
>		      AC_ARG_ENABLE([video-x11-xinerama],
>				    [AS_HELP_STRING([--enable-video-x11-xinerama],
>						    [enable X11 Xinerama support [[default=yes]] ]) ],
>				    [],
>				    [enable_video_x11_xinerama=yes])
>		      AS_IF([test x$enable_video_x11_xinerama = xyes],
>			    [AC_DEFINE([SDL_VIDEO_DRIVER_X11_XINERAMA], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/video/Xext/Xinerama/*.c"])
>		      AC_ARG_ENABLE([video-x11-xrandr],
>				    [AS_HELP_STRING([--enable-video-x11-xrandr],
>						    [enable X11 Xrandr extension for fullscreen [[default=yes]] ]) ],
>				    [],
>				    [enable_video_x11_xrandr=yes])
>		      AS_IF([test x$enable_video_x11_xrandr = xyes],
>			    [definitely_enable_video_x11_xrandr=no
>			     AC_CHECK_HEADER([X11/extensions/Xrandr.h],
>					     [have_xrandr_h_hdr=yes],
>					     [have_xrandr_h_hdr=no],
>					     [[#include <X11/Xlib.h>]])
>			     AS_IF([test x$have_xrandr_h_hdr = xyes],
>				   [AS_IF([test x$enable_x11_shared = xyes -a x$xrandr_lib != x],
>					  [echo "-- dynamic libXrender -> $xrender_lib"
>					   echo "-- dynamic libXrandr -> $xrandr_lib"
>					   AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC_XRENDER], ["$xrender_lib"], [Description])
>					   AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC_XRANDR], ["$xrandr_lib"], [Description])
>					   definitely_enable_video_x11_xrandr=yes],
>					  [AC_CHECK_LIB([Xrender], 
>							[XRenderQueryExtension],
>						        [have_xrender_lib=yes])
>					   AC_CHECK_LIB([Xrandr],
>						       	[XRRQueryExtension], 
>							[have_xrandr_lib=yes])
>					   AS_IF([test x$have_xrender_lib = xyes -a x$have_xrandr_lib = xyes ],
>						 [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lXrandr -lXrender"
>						  definitely_enable_video_x11_xrandr=yes]) ]) ]) ])
>
>            AS_IF([test x$definitely_enable_video_x11_xrandr = xyes],
>		  [AC_DEFINE([SDL_VIDEO_DRIVER_X11_XRANDR], 1,[Description]) ])
>	    AC_ARG_ENABLE([video-x11-xinput],
>			  [AS_HELP_STRING([--enable-video-x11-xinput],
>					  [enable X11 XInput extension for manymouse, tablets, etc [[default=yes]] ]) ],
>			  [],
>			  [enable_video_x11_xinput=yes])
>	    AS_IF([test x$enable_video_x11_xinput = xyes],
>		  [definitely_enable_video_x11_xinput=no
>		   AC_CHECK_HEADER([X11/extensions/XInput.h],
>				   [have_xinput_h_hdr=yes],
>				   [have_xinput_h_hdr=no],
>				   [[#include <X11/Xlib.h>]])
>		   AS_IF([test x$have_xinput_h_hdr = xyes],
>			 [AS_IF([test x$enable_x11_shared = xyes -a x$xinput_lib != x],
>				[echo "-- dynamic libXi -> $xinput_lib"
>				 AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC_XINPUT], ["$xinput_lib"], [Description])
>				 definitely_enable_video_x11_xinput=yes],
>				[AC_CHECK_LIB([Xi], 
>					      [XOpenDevice], 
>					      [have_xinput_lib=yes])
>				 AS_IF([test x$have_xinput_lib = xyes ],
>				       [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lXi"
>					definitely_enable_video_x11_xinput=yes]) ]) ]) ])
>	    AS_IF([test x$definitely_enable_video_x11_xinput = xyes],
>		  [AC_DEFINE([SDL_VIDEO_DRIVER_X11_XINPUT], 1,[Description]) ])
>	    AC_ARG_ENABLE([video-x11-scrnsaver],
>			  [AS_HELP_STRING([--enable-video-x11-scrnsaver],
>					  [enable X11 screensaver extension [[default=yes]] ]) ],
>			  [],
>			  [enable_video_x11_scrnsaver=yes])
>            AS_IF([test x$enable_video_x11_scrnsaver = xyes],
>		  [AC_CHECK_HEADER([X11/extensions/scrnsaver.h],
>				   [have_scrnsaver_h_hdr=yes],
>				   [have_scrnsaver_h_hdr=no],
>				   [[#include <X11/Xlib.h>]])
>		   AS_IF([test x$have_scrnsaver_h_hdr = xyes],
>			 [AS_IF([test x$enable_x11_shared = xyes -a x$xss_lib != x],
>				[echo "-- dynamic libXss -> $xss_lib"
>				 AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_X11_DYNAMIC_XSS], ["$xss_lib"], [Description])
>				 definitely_enable_video_x11_scrnsaver=yes],
>				[AC_CHECK_LIB([Xss], 
>					      [XScreenSaverSuspend],
>					      [have_xss_lib=yes])
>				 AS_IF([test x$have_xss_lib = xyes ],
>				       [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lXss"
>					definitely_enable_video_x11_scrnsaver=yes]) ]) ]) ])
>	    AS_IF([test x$definitely_enable_video_x11_scrnsaver = xyes],
>		  [AC_DEFINE([SDL_VIDEO_DRIVER_X11_SCRNSAVER], 1,[Description]) ])
>            AC_ARG_ENABLE([render-x11],
>			  [AS_HELP_STRING([--enable-render-x11],
>					  [enable the X11 render driver [[default=yes]] ]) ],
>			  [],
>			  [enable_render_x11=yes])
>	    AS_IF([test x$enable_render_x11 = xyes],
>		  [AC_DEFINE([SDL_VIDEO_RENDER_X11], 1,[Description]) ]) ]) ]) ])
>
>dnl Check for QNX photon video driver
>AC_DEFUN([CHECK_PHOTON],
>	 [AC_ARG_ENABLE([video-photon],
>			[AS_HELP_STRING([--enable-video-photon],
>					[use QNX Photon video driver [[default=yes]] ]) ],
>			[],
>			[enable_video_photon=yes])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_photon = xyes],
>	       [AC_MSG_CHECKING(for QNX Photon support)
>	        video_photon=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Ph.h>
>						     #include <Pt.h>
>						     #include <photon/Pg.h>
>						     #include <photon/PdDirect.h>]],
>						   [[PgDisplaySettings_t *visual;]]) ],
>				  [video_photon=yes],
>				  [])
>		AC_MSG_RESULT($video_photon)
>		AS_IF([test x$video_photon = xyes],
>		      [AC_DEFINE([SDL_VIDEO_DRIVER_PHOTON], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/video/photon/*.c"
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lph"
>		       have_video=yes
>		       CHECK_OPENGL_QNX]) ]) ])
>
>dnl Check for QNX photon video driver
>AC_DEFUN([CHECK_QNX_GF],
>	 [AC_ARG_ENABLE([video-qnxgf],
>			[AS_HELP_STRING([--enable-video-qnxgf],
>					[use QNX GF video driver [[default=yes]] ]) ],
>			[],
>			[enable_video_qnxgf=yes])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_qnxgf = xyes],
>	       [AC_MSG_CHECKING([for QNX GF support])
>	        video_qnxgf=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gf/gf.h>
>						     #include <gf/gf3d.h>]],
>						   [[gf_3d_config_info_t* gfinfo;]]) ],
>				  [video_qnxgf=yes],
>				  [])
>		AC_MSG_RESULT($video_qnxgf)
>		AS_IF([test x$video_qnxgf = xyes],
>		      [AC_DEFINE([SDL_VIDEO_DRIVER_QNXGF], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/video/qnxgf/*.c"
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lgf"
>		       dnl Add HIDDI library for HID support using GF
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lhiddi"
>		       have_video=yes
>		       CHECK_OPENGL_ESQNX]) ]) ])
>
>dnl Set up the BWindow video driver if enabled
>AC_DEFUN([CHECK_BWINDOW],
>	 [AS_IF([test x$enable_video = xyes],
>		[AC_DEFINE([SDL_VIDEO_DRIVER_BWINDOW], 1,[Description])
>		 SOURCES="$SOURCES $srcdir/src/video/bwindow/*.cc"
>		 have_video=yes]) ])
>
>dnl Set up the Cocoa video driver for Mac OS X (but not Darwin)
>AC_DEFUN([CHECK_COCOA],
>	 [AC_ARG_ENABLE([video-cocoa],
>			[AS_HELP_STRING([--enable-video-cocoa],
>					[use Cocoa video driver [[default=yes]] ]) ],
>			[],
>			[enable_video_cocoa=yes])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_cocoa = xyes],
>	       [save_CFLAGS="$CFLAGS"
>		dnl work around that we don't have Objective-C support in autoconf
>		CFLAGS="$CFLAGS -x objective-c"
>		AC_MSG_CHECKING([for Cocoa framework])
>		have_cocoa=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#import <Cocoa/Cocoa.h>]],
>						   []) ],
>				  [have_cocoa=yes],
>				  [])
>		AC_MSG_RESULT($have_cocoa)
>		CFLAGS="$save_CFLAGS"
>		AS_IF([test x$have_cocoa = xyes],
>		      [AC_DEFINE([SDL_VIDEO_DRIVER_COCOA], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/video/cocoa/*.m"
>		       have_video=yes]) ]) ])
>
>dnl Find the framebuffer console includes
>AC_DEFUN([CHECK_FBCON],
>	 [AC_ARG_ENABLE([video-fbcon],
>			[AS_HELP_STRING([--enable-video-fbcon],
>					[use framebuffer console video driver [[default=no]] ]) ],
>			[],
>			[enable_video_fbcon=no])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_fbcon = xyes],
>	       [AC_MSG_CHECKING([for framebuffer console support])
>	        video_fbcon=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/fb.h>
>						     #include <linux/kd.h>
>						     #include <linux/keyboard.h>]],
>						   []) ],
>				  [video_fbcon=yes],
>				  [])
>		AC_MSG_RESULT([$video_fbcon])
>		AS_IF([test x$video_fbcon = xyes],
>		      [AC_CHECK_FUNCS([getpagesize])
>		       AC_DEFINE([SDL_VIDEO_DRIVER_FBCON], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/video/fbcon/*.c"
>		       have_video=yes]) ]) ])
>
>dnl Find DirectFB
>AC_DEFUN([CHECK_DIRECTFB],
>	 [AC_ARG_ENABLE([video-directfb],
>			[AS_HELP_STRING([--enable-video-directfb],
>					[use DirectFB video driver [[default=no]] ]) ],
>			[],
>			[enable_video_directfb=no])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_directfb = xyes],
>	       [video_directfb=no
>		DIRECTFB_REQUIRED_VERSION=1.0.0
>		AC_PATH_PROG([DIRECTFBCONFIG], [directfb-config], [no])
>		AS_IF([test x$DIRECTFBCONFIG = xno],
>		      [AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no])
>		       AC_MSG_CHECKING([for DirectFB $DIRECTFB_REQUIRED_VERSION support])
>		       AS_IF([test x$PKG_CONFIG != xno],
>			     [AS_IF([$PKG_CONFIG --atleast-pkgconfig-version 0.7 && $PKG_CONFIG --atleast-version $DIRECTFB_REQUIRED_VERSION directfb],
>				    [DIRECTFB_LIBS=`$PKG_CONFIG --libs directfb`
>				     DIRECTFB_PREFIX=`$PKG_CONFIG --variable=prefix directfb`
>				     video_directfb=yes]) ])
>		       AC_MSG_RESULT($video_directfb)],
>		      [AC_MSG_CHECKING([for DirectFB $DIRECTFB_REQUIRED_VERSION support])
>		       set -- `echo $DIRECTFB_REQUIRED_VERSION | sed 's/\./ /g'`
>		       NEED_VERSION=`expr $1 \* 10000 + $2 \* 100 + $3`
>		       set -- `directfb-config --version | sed 's/\./ /g'`
>		       HAVE_VERSION=`expr $1 \* 10000 + $2 \* 100 + $3`
>		       AS_IF([test $HAVE_VERSION -ge $NEED_VERSION],
>			     [DIRECTFB_CFLAGS=`$DIRECTFBCONFIG --cflags`
>			      DIRECTFB_LIBS=`$DIRECTFBCONFIG --libs`
>			      DIRECTFB_PREFIX=`$DIRECTFBCONFIG --prefix`
>			      video_directfb=yes])
>		       AC_MSG_RESULT([$video_directfb]) ])
>
>		AS_IF([test x$video_directfb = xyes],
>		      [AC_ARG_ENABLE([directfb-shared],
>				     [AS_HELP_STRING([--enable-directfb-shared],
>						     [dynamically load directfb support [[default=yes]] ]) ],
>				     [],
>				     [enable_directfb_shared=yes])
>		      AC_DEFINE([SDL_VIDEO_DRIVER_DIRECTFB], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/video/directfb/*.c"
>		      EXTRA_CFLAGS="$EXTRA_CFLAGS $DIRECTFB_CFLAGS"
>
>		      AC_MSG_CHECKING([for directfb dynamic loading support])
>		      directfb_shared=no
>		      directfb_lib_spec="$DIRECTFB_PREFIX/lib/libdirectfb.so*"
>		      directfb_lib=`ls -- $directfb_lib_spec | sed 's/.*\/$.*$/\1/; q'`
>		      dnl echo "-- $directfb_lib_spec -> $directfb_lib"
>		      AS_IF([test x$have_loadso != xyes -a x$enable_directfb_shared = xyes],
>			    [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic directfb loading]) ])
>		      AS_IF([test x$have_loadso = xyes -a x$enable_directfb_shared = xyes -a x$directfb_lib != x],
>			    [directfb_shared=yes
>			     AC_DEFINE_UNQUOTED([SDL_VIDEO_DRIVER_DIRECTFB_DYNAMIC], ["$directfb_lib"], [Description]) ],
>			    [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $DIRECTFB_LIBS"])
>		      AC_MSG_RESULT($directfb_shared)
>		      have_video=yes]) ]) ])
>
>dnl Find FusionSound
>AC_DEFUN([CHECK_FUSION_SOUND],
>	 [AC_ARG_ENABLE([fusionsound],
>			[AS_HELP_STRING([--enable-fusionsound],
>					[use FusionSound audio driver [[default=no]] ]) ],
>			[],
>			[enable_fusionsound=no])
>	 AS_IF([test x$enable_audio = xyes -a x$enable_fusionsound = xyes],
>	       [fusionsound=no
>		FUSIONSOUND_REQUIRED_VERSION=1.1.1
>		AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
>		AC_MSG_CHECKING(for FusionSound $FUSIONSOUND_REQUIRED_VERSION support)
>		AS_IF([test x$PKG_CONFIG != xno],
>		      [AS_IF([$PKG_CONFIG --atleast-pkgconfig-version 0.7 && $PKG_CONFIG --atleast-version $FUSIONSOUND_REQUIRED_VERSION fusionsound],
>			     [FUSIONSOUND_CFLAGS=`$PKG_CONFIG --cflags fusionsound`
>			      FUSIONSOUND_LIBS=`$PKG_CONFIG --libs fusionsound`
>			      fusionsound=yes]) ])
>	 AC_MSG_RESULT($fusionsound)
>
>	 AS_IF([test x$fusionsound = xyes],
>	       [AC_DEFINE([SDL_AUDIO_DRIVER_FUSIONSOUND], 1,[Description])
>	        SOURCES="$SOURCES $srcdir/src/audio/fusionsound/*.c"
>		EXTRA_CFLAGS="$EXTRA_CFLAGS $FUSIONSOUND_CFLAGS"
>		AC_ARG_ENABLE([fusionsound-shared],
>			      [AS_HELP_STRING([--enable-fusionsound-shared],
>					      [dynamically load fusionsound audio support [[default=yes]] ]) ],
>			      [],
>			      [enable_fusionsound_shared=yes])
>		fusionsound_shared=no
>		AC_MSG_CHECKING([for FusionSound dynamic loading support])
>		AS_IF([test x$have_loadso != xyes -a x$enable_fusionsound_shared = xyes],
>		      [AC_MSG_WARN([You must have SDL_LoadObject() support for dynamic fusionsound loading]) ])
>		AS_IF([test x$have_loadso = xyes -a x$enable_fusionsound_shared = xyes],
>		      [AC_DEFINE_UNQUOTED([SDL_AUDIO_DRIVER_FUSIONSOUND_DYNAMIC], ["libfusionsound.so"], [Description])
>		       fusionsound_shared=yes],
>		      [EXTRA_LDFLAGS="$EXTRA_LDFLAGS $FUSIONSOUND_LIBS"])
>	        AC_MSG_RESULT([$fusionsound_shared])
>		have_audio=yes]) ]) ])
>
>dnl See if we're running on PlayStation 2 hardware
>AC_DEFUN([CHECK_PS2_GS],
>	 [AC_ARG_ENABLE([video-ps2gs],
>			[AS_HELP_STRING([--enable-video-ps2gs],
>					[use PlayStation 2 GS video driver [[default=no]] ]) ],
>			[],
>			[enable_video_ps2gs=no])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_ps2gs = xyes],
>	       [AC_MSG_CHECKING(for PlayStation 2 GS support)
>	       video_ps2gs=no
>	       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ps2/dev.h>
>						    #include <linux/ps2/gs.h>]], 
>						  [])],
>				 [video_ps2gs=yes],
>				 [])
>	       AC_MSG_RESULT($video_ps2gs)
>	       AS_IF([test x$video_ps2gs = xyes],
>		     [AC_DEFINE([SDL_VIDEO_DRIVER_PS2GS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/video/ps2gs/*.c"
>		      have_video=yes]) ]) ])
>
>dnl See if we're running on PlayStation 3 Cell hardware
>AC_DEFUN([CHECK_PS3],
>	 [AC_ARG_ENABLE([video-ps3],
>			[AS_HELP_STRING([--enable-video-ps3],
>					[use PlayStation 3 Cell driver [[default=yes]] ]) ],
>			[],
>			[enable_video_ps3=yes])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_ps3 = xyes],
>	       [video_ps3=no
>		AC_CHECK_HEADER([linux/fb.h])
>		AC_CHECK_HEADER([asm/ps3fb.h], 
>				[have_ps3fb_hdr=yes], 
>				[],
>				[[#ifndef _LINUX_TYPES_H
>				  #include <linux/types.h>
>				  #endif]])
>		AC_CHECK_HEADER([libspe2.h], have_libspe2_hdr=yes)
>		AC_CHECK_LIB([spe2], spe_context_create, have_spe2_lib=yes)
>		AC_CHECK_PROGS(SPU_GCC, [spu-gcc])
>		AC_CHECK_PROGS(EMBEDSPU, [embedspu])
>		have_spu_libs=yes
>		AC_CHECK_LIB([fb_writer_spu], [main], [], [have_spu_libs=no])
>		AC_CHECK_LIB([yuv2rgb_spu], [main], [], [have_spu_libs=no])
>		AC_CHECK_LIB([bilin_scaler_spu], [main], [], [have_spu_libs=no])
>		AS_IF([test x$have_ps3fb_hdr = xyes -a x$have_libspe2_hdr = xyes -a x$have_spe2_lib = xyes -a "$SPU_GCC" -a "$EMBEDSPU"],
>		      [AC_DEFINE([SDL_VIDEO_DRIVER_PS3], 1,[Description])
>		       video_ps3=yes
>		       have_video=yes
>		       SOURCES="$SOURCES $srcdir/src/video/ps3/*.c"
>		       EXTRA_CFLAGS="$EXTRA_CFLAGS -I/opt/cell/sdk/usr/include"
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -L/opt/cell/sdk/usr/lib -lspe2 -lfb_writer_spu -lyuv2rgb_spu -lbilin_scaler_spu"
>		       AS_IF([test x$have_spu_libs = xno],
>			     [AC_MSG_WARN([ps3libs missing, please run make ps3libs]) ]) ])
>		AC_MSG_CHECKING([for PlayStation 3 Cell support])
>		AC_MSG_RESULT([$video_ps3]) ]) ])
>
>dnl Find the SVGAlib includes and libraries
>AC_DEFUN([CHECK_SVGA],
>	 [AC_ARG_ENABLE([video-svga],
>			[AS_HELP_STRING([--enable-video-svga],
>					[use SVGAlib video driver [[default=no]] ]) ],
>			[],
>			[enable_video_svga=no])
>	 AS_IF([test x$enable_video = xyes -a x$enable_video_svga = xyes],
>	       [AC_MSG_CHECKING([for SVGAlib (1.4.0+) support])
>	        video_svga=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <vga.h>
>						     #include <vgamouse.h>
>						     #include <vgakeyboard.h>]],
>						   [[if ( SCANCODE_RIGHTWIN && SCANCODE_LEFTWIN ) 
>						     { exit(0); } ]]) ],
>				  [video_svga=yes],
>				  [])
>		AC_MSG_RESULT($video_svga)
>		AS_IF([test x$video_svga = xyes],
>		      [AC_DEFINE([SDL_VIDEO_DRIVER_SVGALIB], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/video/svga/*.c"
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lvga"
>		       have_video=yes]) ]) ])
>
>dnl rcg04172001 Set up the Null video driver.
>AC_DEFUN([CHECK_DUMMY_VIDEO],
>	 [AC_ARG_ENABLE([video-dummy],
>			[AS_HELP_STRING([--enable-video-dummy],
>					[use dummy video driver [[default=yes]] ]) ],
>			[],
>			[enable_video_dummy=yes])
>	 AS_IF([test x$enable_video_dummy = xyes],
>	       [AC_DEFINE([SDL_VIDEO_DRIVER_DUMMY], 1,[Description])
>	       SOURCES="$SOURCES $srcdir/src/video/dummy/*.c"
>	       have_video=yes]) ])
>
>dnl Check to see if OpenGL support is desired
>AC_ARG_ENABLE([video-opengl],
>	      [AS_HELP_STRING([--enable-video-opengl],
>			      [include OpenGL support [[default=yes]] ]) ],
>	      [],
>	      [enable_video_opengl=yes])
>
>dnl Find OpenGL
>AC_DEFUN([CHECK_OPENGL_X11],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_MSG_CHECKING(for OpenGL (GLX) support)
>		video_opengl=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>
>						     #include <GL/glx.h>
>						     #include <GL/glu.h>]],
>						   []) ],
>				  [video_opengl=yes],
>				  [])
>		AC_MSG_RESULT([$video_opengl])
>		AS_IF([test x$video_opengl = xyes],
>		      [AC_DEFINE([SDL_VIDEO_OPENGL], 1,[Description])
>		       AC_DEFINE([SDL_VIDEO_OPENGL_GLX], 1,[Description])
>		       AC_DEFINE([SDL_VIDEO_RENDER_OGL], 1,[Description]) ]) ]) ])
>
>dnl Find QNX 6.x Software OpenGL
>AC_DEFUN([CHECK_OPENGL_QNX],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_MSG_CHECKING([for QNX 6.x Photon OpenGL support])
>		 video_opengl=no
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]],
>						    []) ],
>				   [video_opengl=yes],
>				   [])
>		 AC_MSG_RESULT([$video_opengl])
>		 AS_IF([test x$video_opengl = xyes],
>		       [AC_DEFINE([SDL_VIDEO_OPENGL], 1,[Description])
>		        AC_DEFINE([SDL_VIDEO_RENDER_OGL], 1,[Description])
>		        EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lGL"]) ]) ])
>
>dnl Find QNX 6.3 and above OpenGL ES implementation
>AC_DEFUN([CHECK_OPENGL_ESQNX],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_MSG_CHECKING([for QNX OpenGL ES (CM) support])
>		 video_opengl=no
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GLES/egl.h>]],
>						    []) ],
>				   [video_opengl=yes],
>				   [])
>		 AC_MSG_RESULT($video_opengl)
>		 AS_IF([test x$video_opengl = xyes],
>		       [AC_DEFINE([SDL_VIDEO_OPENGL_ES], 1,[Description])
>		        AC_DEFINE([SDL_VIDEO_RENDER_OGL_ES], 1,[Description])
>			EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lGLES_CM"],
>		       [AC_MSG_CHECKING([for QNX OpenGL ES (CL) support])
>			video_opengl=no
>			AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define COMMON_LITE
>							     #include <GLES/egl.h>]],
>							   []) ],
>					  [video_opengl=yes],
>					  [])
>			AC_MSG_RESULT($video_opengl)
>			AS_IF([test x$video_opengl = xyes],
>			      [AC_DEFINE([SDL_VIDEO_OPENGL_ES], 1,[Description])
>			       AC_DEFINE([SDL_VIDEO_RENDER_OGL_ES], 1,[Description])
>			       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lGLES_CLS"]) ]) ]) ])
>
>dnl Check for Win32 OpenGL
>AC_DEFUN([CHECK_GL_WIN32],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_DEFINE([SDL_VIDEO_OPENGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_OPENGL_WGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_RENDER_OGL], 1,[Description]) ]) ])
>
>dnl Check for BeOS OpenGL
>AC_DEFUN([CHECK_GL_BE],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_DEFINE([SDL_VIDEO_OPENGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_OPENGL_BGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_RENDER_OGL], 1,[Description])
>		 EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lGL"]) ])
>
>dnl Check for MacOS OpenGL
>AC_DEFUN([CHECK_GL_MAC],
>	 [AS_IF([test x$enable_video = xyes -a x$enable_video_opengl = xyes],
>		[AC_DEFINE([SDL_VIDEO_OPENGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_OPENGL_CGL], 1,[Description])
>		 AC_DEFINE([SDL_VIDEO_RENDER_OGL], 1,[Description])
>		 AS_CASE(["$host"],
>			 [*-*-darwin*],
>			 [AS_IF([test x$enable_video_cocoa = xyes],
>				[EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,OpenGL"]) ]) ]) ])
>
>dnl See if we can use the new unified event interface in Linux 2.4
>AC_DEFUN([CHECK_INPUT_EVENTS],
>	 [dnl Check for Linux 2.4 unified input event interface support
>	  AC_ARG_ENABLE([input-events],
>			[AS_HELP_STRING([--enable-input-events],
>					[use Linux 2.4 unified input interface [[default=yes]] ]) ],
>			[],
>			[enable_input_events=yes])
>	  AS_IF([test x$enable_input_events = xyes],
>		[AC_MSG_CHECKING([for Linux 2.4 unified input interface])
>		 use_input_events=no
>		 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/input.h>
>						      #ifndef EVIOCGNAME
>						      #error EVIOCGNAME() ioctl not available
>						      #endif]],
>						    []) ],
>				   [use_input_events=yes],
>				   [])
>		 AC_MSG_RESULT([$use_input_events])
>		 AS_IF([test x$use_input_events = xyes],
>		       [AC_DEFINE([SDL_INPUT_LINUXEV], 1,[Description]) ]) ]) ])
>
>dnl See if we can use the Touchscreen input library
>AC_DEFUN([CHECK_TSLIB],
>	 [AC_ARG_ENABLE([input-tslib],
>			[AS_HELP_STRING([--enable-input-tslib],
>					[use the Touchscreen library for input [[default=yes]] ]) ],
>			[],
>			[enable_input_tslib=yes])
>	 AS_IF([test x$enable_input_tslib = xyes],
>	       [AC_MSG_CHECKING([for Touchscreen library support])
>	        enable_input_tslib=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "tslib.h"]],
>						   []) ],
>				  [enable_input_tslib=yes],
>				  [])
>        AC_MSG_RESULT([$enable_input_tslib])
>        AS_IF([test x$enable_input_tslib = xyes],
>	      [AC_DEFINE([SDL_INPUT_TSLIB], 1,[Description])
>	       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lts"]) ]) ])
>
>dnl See if we can use GNU pth library for threads
>AC_DEFUN([CHECK_PTH],
>	 [dnl Check for pth support
>	  AC_ARG_ENABLE([pth],
>			[AS_HELP_STRING([--enable-pth],
>					[use GNU pth library for multi-threading [[default=yes]] ]) ],
>			[],
>			[enable_pth=yes])
>	  AS_IF([test x$enable_threads = xyes -a x$enable_pth = xyes],
>		[AC_PATH_PROG(PTH_CONFIG, pth-config, no)
>		 AS_IF([test "$PTH_CONFIG" = "no"],
>		       [use_pth=no],
>		       [use_pth=yes])
>		 AC_MSG_CHECKING([pth])
>		 AC_MSG_RESULT([$use_pth])
>		 AS_IF([test "x$use_pth" = xyes],
>		       [AC_DEFINE([SDL_THREAD_PTH], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/thread/pth/*.c"
>		       SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syssem.c"
>		       SDL_CFLAGS="$SDL_CFLAGS `$PTH_CONFIG --cflags`"
>		       SDL_LIBS="$SDL_LIBS `$PTH_CONFIG --libs --all`"
>		       have_threads=yes]) ]) ])
>
>dnl See what type of thread model to use on Linux and Solaris
>AC_DEFUN([CHECK_PTHREADS],
>	 [dnl Check for pthread support
>	  AC_ARG_ENABLE([pthreads],
>			[AS_HELP_STRING([--enable-pthreads],
>					[use POSIX threads for multi-threading [[default=yes]] ]) ],
>			[],
>			[enable_pthreads=yes])
>	  dnl This is used on Linux for glibc binary compatibility (Doh!)
>	  AC_ARG_ENABLE([pthread-sem],
>			[AS_HELP_STRING([--enable-pthread-sem],
>					[use pthread semaphores [[default=yes]] ]) ],
>			[],
>			[enable_pthread_sem=yes])
>	  AS_CASE(["$host"],
>		  [*-*-linux*|*-*-uclinux*],
>		  [pthread_cflags="-D_REENTRANT"
>		   pthread_lib="-lpthread"],
>		  [*-*-bsdi*],
>		  [pthread_cflags="-D_REENTRANT -D_THREAD_SAFE"
>		   pthread_lib=""],
>		  [*-*-darwin*],
>		  [pthread_cflags="-D_THREAD_SAFE"
>		   dnl causes Carbon.p complaints?
>		   dnl pthread_cflags="-D_REENTRANT -D_THREAD_SAFE"
>		  ],
>		  [*-*-freebsd*|*-*-dragonfly*],
>		  [pthread_cflags="-D_REENTRANT -D_THREAD_SAFE"
>		   pthread_lib="-pthread"],
>		  [*-*-netbsd*],
>		  [pthread_cflags="-D_REENTRANT -D_THREAD_SAFE"
>		   pthread_lib="-lpthread"],
>		  [*-*-openbsd*],
>		  [pthread_cflags="-D_REENTRANT"
>		   pthread_lib="-pthread"],
>		  [*-*-solaris*],
>		  [pthread_cflags="-D_REENTRANT"
>		   pthread_lib="-lpthread -lposix4"],
>		  [*-*-sysv5*],
>		  [pthread_cflags="-D_REENTRANT -Kthread"
>		   pthread_lib=""],
>		  [*-*-irix*],
>		  [pthread_cflags="-D_SGI_MP_SOURCE"
>		   pthread_lib="-lpthread"],
>		  [*-*-aix*],
>		  [pthread_cflags="-D_REENTRANT -mthreads"
>		   pthread_lib="-lpthread"],
>		  [*-*-hpux11*],
>		  [pthread_cflags="-D_REENTRANT"
>		   pthread_lib="-L/usr/lib -lpthread"],
>		  [*-*-qnx*],
>		  [pthread_cflags=""
>		   pthread_lib=""],
>		  [*-*-osf*],
>		  [pthread_cflags="-D_REENTRANT"
>		   AS_IF([test x$ac_cv_c_compiler_gnu = xyes],
>			 [pthread_lib="-lpthread -lrt"],
>			 [pthread_lib="-lpthread -lexc -lrt"]) ],
>		  [*],
>		  [pthread_cflags="-D_REENTRANT"
>		   pthread_lib="-lpthread"])
>	  AS_IF([test x$enable_threads = xyes -a x$enable_pthreads = xyes],
>		[dnl Save the original compiler flags and libraries
>		 ac_save_cflags="$CFLAGS"; ac_save_libs="$LIBS"
>		 dnl Add the pthread compiler flags and libraries
>		 CFLAGS="$CFLAGS $pthread_cflags"; LIBS="$LIBS $pthread_lib"
>		 dnl Check to see if we have pthread support on this system
>		 AC_MSG_CHECKING([for pthreads])
>		 use_pthreads=no
>		 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
>						 [[pthread_attr_t type;
>						   pthread_attr_init(&type);]]) ],
>				[use_pthreads=yes],
>				[])
>		 AC_MSG_RESULT([$use_pthreads])
>		 dnl Restore the compiler flags and libraries
>		 CFLAGS="$ac_save_cflags"; LIBS="$ac_save_libs"
>		 dnl Do futher testing if we have pthread support...
>		 AS_IF([test x$use_pthreads = xyes],
>		       [AC_DEFINE([SDL_THREAD_PTHREAD], 1,[Description])
>		        EXTRA_CFLAGS="$EXTRA_CFLAGS $pthread_cflags"
>			EXTRA_LDFLAGS="$EXTRA_LDFLAGS $pthread_lib"
>			SDL_CFLAGS="$SDL_CFLAGS $pthread_cflags"
>			SDL_LIBS="$SDL_LIBS $pthread_lib"
>			dnl TODO: Do this saving in a standard way (perhaps use a macro?)
>			dnl Save the original compiler flags and libraries
>			ac_save_cflags="$CFLAGS"
>			ac_save_libs="$LIBS"
>			dnl Add the pthread compiler flags and libraries
>			CFLAGS="$CFLAGS $pthread_cflags"
>			LIBS="$LIBS $pthread_lib"
>			dnl Check to see if recursive mutexes are available
>			AC_MSG_CHECKING([for recursive [mutexes]])
>			has_recursive_mutexes=no
>			AS_IF([test x$has_recursive_mutexes = xno],
>			      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
>								  [[pthread_mutexattr_t attr;
>								    pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);]]) ],
>						 [has_recursive_mutexes=yes
>						  AC_DEFINE([SDL_THREAD_PTHREAD_RECURSIVE_MUTEX], 1,[Description])],
>						 []) ])
>			AS_IF([test x$has_recursive_mutexes = xno],
>			      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
>								  [[pthread_mutexattr_t attr;
>								    pthread_mutexattr_setkind_np(&attr, PTHREAD_MUTEX_RECURSIVE_NP); ]]) ],
>						 [has_recursive_mutexes=yes
>						  AC_DEFINE([SDL_THREAD_PTHREAD_RECURSIVE_MUTEX_NP], 1,[Description]) ],
>						 []) ])
>			AC_MSG_RESULT([$has_recursive_mutexes])
>			dnl Check to see if pthread semaphore support is missing
>			AS_IF([test x$enable_pthread_sem = xyes],
>			      [AC_MSG_CHECKING([for pthread semaphores])
>			       have_pthread_sem=no
>			       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>
>								    #include <semaphore.h>]],
>								  []) ],
>						 [have_pthread_sem=yes],
>						 [])
>			       AC_MSG_RESULT([$have_pthread_sem]) ])
>			dnl Restore the compiler flags and libraries
>			CFLAGS="$ac_save_cflags"; LIBS="$ac_save_libs"
>			dnl Basic thread creation functions
>			SOURCES="$SOURCES $srcdir/src/thread/pthread/SDL_systhread.c"
>			dnl Semaphores
>			dnl We can fake these with mutexes and condition variables if necessary
>			AS_IF([test x$have_pthread_sem = xyes],
>			      [SOURCES="$SOURCES $srcdir/src/thread/pthread/SDL_syssem.c"],
>			      [SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syssem.c"])
>			dnl Mutexes
>			dnl We can fake these with semaphores if necessary
>			SOURCES="$SOURCES $srcdir/src/thread/pthread/SDL_sysmutex.c"
>			dnl Condition variables
>			dnl We can fake these with semaphores and mutexes if necessary
>			SOURCES="$SOURCES $srcdir/src/thread/pthread/SDL_syscond.c"
>			have_threads=yes],
>		       [CheckPTH]) ]) ])
>
>dnl Determine whether the compiler can produce Win32 executables
>AC_DEFUN([CHECK_WIN32],
>	 [AC_MSG_CHECKING([Win32 compiler])
>	  have_win32_gcc=no
>	  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <windows.h>]],
>					     []) ],
>			    [have_win32_gcc=yes],
>			    [])
>	  AC_MSG_RESULT([$have_win32_gcc])
>	  AS_IF([test x$have_win32_gcc != xyes],
>		[AC_MSG_ERROR([Your compiler ($CC) does not produce Win32 executables!]) ])
>	  AC_MSG_CHECKING([Windows CE])
>	  have_wince=no
>	  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifndef _WIN32_WCE
>			   		       #error This is not Windows CE
>					       #endif]],
>					     []) ],
>			    [have_wince=yes],
>			    [])
>	  AC_MSG_RESULT([$have_wince])
>	  dnl See if the user wants to redirect standard output to files
>	  AC_ARG_ENABLE([stdio-redirect],
>			[AS_HELP_STRING([--enable-stdio-redirect],
>					[Redirect STDIO to files on Win32 [[default=yes]] ]) ],
>			[],
>			[enable_stdio_redirect=yes])
>	  AS_IF([test x$enable_stdio_redirect != xyes],
>		[EXTRA_CFLAGS="$EXTRA_CFLAGS -DNO_STDIO_REDIRECT"]) ])
>
>dnl Find the DirectX includes and libraries
>AC_DEFUN([CHECK_DIRECTX],
>	 [AC_ARG_ENABLE([directx],
>			[AS_HELP_STRING([--enable-directx],
>					[use DirectX for Win32 audio/video [[default=yes]] ]) ],
>			[],
>			[enable_directx=yes])
>	 AS_IF([test x$enable_directx = xyes],
>	       [AC_CHECK_HEADER([d3d9.h], [have_d3d=yes])
>	        AC_CHECK_HEADER([ddraw.h], [have_ddraw=yes])
>		AC_CHECK_HEADER([dsound.h], [have_dsound=yes])
>		AC_CHECK_HEADER([dinput.h], [have_dinput=yes]) ]) ])
>
>dnl Check for the dlfcn.h interface for dynamically loading objects
>dnl TODO: Libtool part libltdl can do this, too
>AC_DEFUN([CHECK_DLOPEN],
>	 [AC_ARG_ENABLE([sdl-dlopen],
>			[AS_HELP_STRING([--enable-sdl-dlopen],
>					[use dlopen for shared object loading [[default=yes]] ]) ],
>			[],
>			[enable_sdl_dlopen=yes])
>	 AS_IF([test x$enable_sdl_dlopen = xyes],
>	       [AC_MSG_CHECKING([for dlopen])
>	        have_dlopen=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <dlfcn.h>
>						     #if defined(MAC_OS_X_VERSION_MIN_REQUIRED) && MAC_OS_X_VERSION_MIN_REQUIRED <= 1020
>						     #error Use dlcompat for Mac OS X 10.2 compatibility
>						     #endif]],
>						   []) ],
>				  [have_dlopen=yes],
>				  [])
>		AC_MSG_RESULT([$have_dlopen])
>		AS_IF([test x$have_dlopen = xyes],
>		      [AC_CHECK_LIB([c], 
>				    [dlopen], 
>				    [EXTRA_LDFLAGS="$EXTRA_LDFLAGS"],
>				    [AC_CHECK_LIB([dl],
>						  [dlopen],
>						  [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -ldl"],
>						  [AC_CHECK_LIB([ltdl],
>							       	[dlopen],
>							       	[EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lltdl"]) ]) ])
>		       AC_CHECK_LIB([dl],
>				    [dlvsym],
>				    [have_dlvsym=yes])
>		       AS_IF([test x$have_dlvsym = xyes],
>			     [AC_DEFINE([HAVE_DLVSYM], 1,[Description]) ])
>		       AC_DEFINE([SDL_LOADSO_DLOPEN], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/loadso/dlopen/*.c"
>		       have_loadso=yes]) ]) ])
>
>dnl Check for the usbhid(3) library on *BSD
>AC_DEFUN([CHECK_USBHID],
>	 [AS_IF([test x$enable_joystick = xyes],
>		[AC_CHECK_LIB([usbhid],
>			      [hid_init],
>			      [have_libusbhid=yes])
>		AS_IF([test x$have_libusbhid = xyes],
>		      [AC_CHECK_HEADER([usbhid.h], [USB_CFLAGS="-DHAVE_USBHID_H"])
>		       AC_CHECK_HEADER([libusbhid.h], [USB_CFLAGS="-DHAVE_LIBUSBHID_H"])
>		       USB_LIBS="$USB_LIBS -lusbhid"],
>		      [AC_CHECK_HEADER([usb.h], [USB_CFLAGS="-DHAVE_USB_H"])
>		       AC_CHECK_HEADER([libusb.h], [USB_CFLAGS="-DHAVE_LIBUSB_H"])
>		       AC_CHECK_LIB([usb],
>				    [hid_init],
>				    [USB_LIBS="$USB_LIBS -lusb"]) ])
>		save_CFLAGS="$CFLAGS"
>		CFLAGS="$CFLAGS $USB_CFLAGS"
>		AC_MSG_CHECKING([for usbhid])
>		have_usbhid=no
>		AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
>						     #if defined(HAVE_USB_H)
>						     #include <usb.h>
>						     #endif
>						     #ifdef __DragonFly__
>						     # include <bus/usb/usb.h>
>						     # include <bus/usb/usbhid.h>
>						     #else
>						     # include <dev/usb/usb.h>
>						     # include <dev/usb/usbhid.h>
>						     #endif
>						     #if defined(HAVE_USBHID_H)
>						     #include <usbhid.h>
>						     #elif defined(HAVE_LIBUSB_H)
>						     #include <libusb.h>
>						     #elif defined(HAVE_LIBUSBHID_H)
>						     #include <libusbhid.h>
>						     #endif]],
>						   [[struct report_desc *repdesc;
>						     struct usb_ctl_report *repbuf;
>						     hid_kind_t hidkind;]]) ],
>				  [have_usbhid=yes],
>				  [])
>		AC_MSG_RESULT([$have_usbhid])
>		AS_IF([test x$have_usbhid = xyes],
>		      [AC_MSG_CHECKING(for ucr_data member of usb_ctl_report)
>		       have_usbhid_ucr_data=no
>		       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
>							    #if defined(HAVE_USB_H)
>							    #include <usb.h>
>							    #endif
>							    #ifdef __DragonFly__
>							    # include <bus/usb/usb.h>
>							    # include <bus/usb/usbhid.h>
>							    #else
>							    # include <dev/usb/usb.h>
>							    # include <dev/usb/usbhid.h>
>							    #endif
>							    #if defined(HAVE_USBHID_H)
>							    #include <usbhid.h>
>							    #elif defined(HAVE_LIBUSB_H)
>							    #include <libusb.h>
>							    #elif defined(HAVE_LIBUSBHID_H)
>							    #include <libusbhid.h>
>							    #endif]],
>							  [[struct usb_ctl_report buf;
>							    if (buf.ucr_data) { }]]) ],
>				  [have_usbhid_ucr_data=yes],
>				  [])
>		       AS_IF([test x$have_usbhid_ucr_data = xyes],
>			     [USB_CFLAGS="$USB_CFLAGS -DUSBHID_UCR_DATA"])
>		       AC_MSG_RESULT([$have_usbhid_ucr_data])
>		       AC_MSG_CHECKING([for new usbhid API])
>		       have_usbhid_new=no
>		       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
>							    #if defined(HAVE_USB_H)
>							    #include <usb.h>
>							    #endif
>							    #ifdef __DragonFly__
>							    #include <bus/usb/usb.h>
>							    #include <bus/usb/usbhid.h>
>							    #else
>							    #include <dev/usb/usb.h>
>							    #include <dev/usb/usbhid.h>
>							    #endif
>							    #if defined(HAVE_USBHID_H)
>							    #include <usbhid.h>
>							    #elif defined(HAVE_LIBUSB_H)
>							    #include <libusb.h>
>							    #elif defined(HAVE_LIBUSBHID_H)
>							    #include <libusbhid.h>
>							    #endif]],
>							  [[report_desc_t d;
>							    hid_start_parse(d, 1, 1);]]) ],
>				  [have_usbhid_new=yes],
>				  [])
>		       AS_IF([test x$have_usbhid_new = xyes],
>			     [USB_CFLAGS="$USB_CFLAGS -DUSBHID_NEW"])
>		       AC_MSG_RESULT([$have_usbhid_new])
>		       AC_MSG_CHECKING(for struct joystick in machine/joystick.h)
>		       have_machine_joystick=no
>		       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <machine/joystick.h>]],
>							  [[struct joystick t;]]) ],
>					 [have_machine_joystick=yes],
>					 [])
>		       AS_IF([test x$have_machine_joystick = xyes],
>			     [AC_DEFINE([SDL_JOYSTICK_USBHID_MACHINE_JOYSTICK_H], 1,[Description]) ])
>		       AC_MSG_RESULT([$have_machine_joystick])
>		       AC_DEFINE([SDL_JOYSTICK_USBHID], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/joystick/bsd/*.c"
>		       EXTRA_CFLAGS="$EXTRA_CFLAGS $USB_CFLAGS"
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS $USB_LIBS"
>		       have_joystick=yes])
>		CFLAGS="$save_CFLAGS"]) ])
>
>dnl Check for clock_gettime()
>AC_DEFUN([CHECK_CLOCK_GETTIME],
>	 [AC_ARG_ENABLE([clock_gettime],
>			[AS_HELP_STRING([--enable-clock_gettime],
>					[use clock_gettime() instead of gettimeofday() on UNIX [[default=no]] ]) ],
>			[],
>			[enable_clock_gettime=no])
>	 AS_IF([test x$enable_clock_gettime = xyes],
>	       [AC_CHECK_LIB(rt, clock_gettime, have_clock_gettime=yes)
>	        AS_IF([test x$have_clock_gettime = xyes],
>		      [AC_DEFINE([HAVE_CLOCK_GETTIME], 1,[Description])
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lrt"],
>		      [AC_CHECK_LIB([c],
>				    [clock_gettime], 
>				    [have_clock_gettime=yes])
>		       AS_IF([test x$have_clock_gettime = xyes],
>			     [AC_DEFINE([HAVE_CLOCK_GETTIME], 1,[Description])
>			      EXTRA_LDFLAGS="$EXTRA_LDFLAGS"]) ]) ]) ])
>
>dnl Check for a valid linux/version.h
>AC_DEFUN([CHECK_LINUX_VERSION],
>	 [AC_CHECK_HEADER([linux/version.h],
>			  [have_linux_version_h=yes])
>	  AS_IF([test x$have_linux_version_h = xyes],
>		[EXTRA_CFLAGS="$EXTRA_CFLAGS -DHAVE_LINUX_VERSION_H"]) ])
>
>dnl Check if we want to use RPATH
>AC_DEFUN([CHECK_RPATH],
>	 [AC_ARG_ENABLE([rpath],
>			[AS_HELP_STRING([--enable-rpath],
>					[use an rpath when linking SDL [[default=yes]] ]) ],
>			[],
>			[enable_rpath=yes]) ])
>
>dnl Set up the configuration based on the host platform!
>AS_CASE(["$host"],
>	[arm-*-elf*], dnl FIXME: Can we get more specific for iPodLinux?
>	[ARCH=linux
>	 CHECK_DUMMY_VIDEO
>	 dnl CheckIPod dnl not implemented ATM
>	 dnl Set up files for the timer library
>	 AS_IF([test x$enable_timers = xyes],
>	       [AC_DEFINE([SDL_TIMER_UNIX], 1,[Description])
>	        SOURCES="$SOURCES $srcdir/src/timer/unix/*.c"
>	        have_timers=yes]) ],
>	[*-*-linux*|*-*-uclinux*|*-*-gnu*|*-*-k*bsd*-gnu|*-*-bsdi*|*-*-freebsd*|*-*-dragonfly*|*-*-netbsd*|*-*-openbsd*|*-*-sysv5*|*-*-solaris*|*-*-hpux*|*-*-irix*|*-*-aix*|*-*-osf*|*-*-minix*],
>	[AS_CASE(["$host"],
>		 [*-*-linux*],
>		 [ARCH=linux],
>		 [*-*-uclinux*],
>		 [ARCH=linux],
>		 [*-*-kfreebsd*-gnu],
>		 [ARCH=kfreebsd-gnu],
>		 [*-*-knetbsd*-gnu],
>		 [ARCH=knetbsd-gnu],
>		 [*-*-kopenbsd*-gnu],
>		 [ARCH=kopenbsd-gnu],
>		 [*-*-gnu*],
>		 [ARCH=gnu], dnl must be last of the gnu variants
>		 [*-*-bsdi*],
>		 [ARCH=bsdi],
>		 [*-*-freebsd*],
>		 [ARCH=freebsd],
>		 [*-*-dragonfly*],
>		 [ARCH=freebsd],
>		 [*-*-netbsd*],
>		 [ARCH=netbsd],
>		 [*-*-openbsd*],
>		 [ARCH=openbsd],
>		 [*-*-sysv5*],
>		 [ARCH=sysv5],
>		 [*-*-solaris*],
>		 [ARCH=solaris],
>		 [*-*-hpux*],
>		 [ARCH=hpux],
>		 [*-*-irix*],
>		 [ARCH=irix],
>		 [*-*-aix*],
>		 [ARCH=aix],
>		 [*-*-osf*],
>		 [ARCH=osf],
>		 [*-*-minix*],
>		 [ARCH=minix])
>	CHECK_VISIBILITY_HIDDEN
>	CHECK_DUMMY_VIDEO
>	CHECK_DISC_AUDIO
>	CHECK_DUMMY_AUDIO
>	CHECK_DLOPEN
>	CHECK_OSS
>	CHECK_DMEDIA
>	CHECK_MME
>	CHECK_ALSA
>	CHECK_PULSEAUDIO
>	CHECK_ARTS
>	CHECK_ESD
>	CHECK_NAS
>	CHECK_X11
>	CHECK_FBCON
>	CHECK_DIRECTFB
>	CHECK_FUSION_SOUND
>	CHECK_PS2_GS
>	CHECK_PS3
>	CHECK_SVGA
>	CHECK_OPENGL_X11
>	CHECK_INPUT_EVENTS
>	CHECK_TSLIB
>	CHECK_USBHID
>	CHECK_PTHREADS
>	CHECK_CLOCK_GETTIME
>	CHECK_LINUX_VERSION
>	CHECK_RPATH
>        dnl Set up files for the audio library
>        AS_IF([test x$enable_audio = xyes],
>	      [AS_CASE([$ARCH],
>		       [sysv5|solaris|hpux],
>		       [AC_DEFINE([SDL_AUDIO_DRIVER_SUNAUDIO], 1,[Description])
>			SOURCES="$SOURCES $srcdir/src/audio/sun/*.c"
>			have_audio=yes],
>		       [netbsd|openbsd],
>		       [AC_DEFINE([SDL_AUDIO_DRIVER_BSD], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/audio/bsd/*.c"
>			have_audio=yes],
>		       [aix],
>		       [AC_DEFINE([SDL_AUDIO_DRIVER_PAUDIO], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/audio/paudio/*.c"
>			have_audio=yes]) ])
>
>	dnl Set up files for the atomic operations library
>        AS_IF([test x$enable_atomic = xyes],
>	      [AS_CASE([$ARCH],
>		       [linux],
>		       [AC_DEFINE([SDL_ATOMIC_LINUX], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/atomic/linux/*.c"
>			have_atomic=yes]) ])
>
>	dnl Set up files for the joystick library
>        AS_IF([test x$enable_joystick = xyes],
>	      [AS_CASE([$ARCH],
>		       [linux],
>		       [AC_DEFINE([SDL_JOYSTICK_LINUX], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/joystick/linux/*.c"
>			have_joystick=yes]) ])
>
>	dnl Set up files for the haptic library
>        AS_IF([test x$enable_haptic = xyes],
>	      [AS_IF([test x$use_input_events = xyes],
>		     [AS_CASE([$ARCH],
>			      [linux],
>			      [AC_DEFINE([SDL_HAPTIC_LINUX], 1,[Description])
>			       SOURCES="$SOURCES $srcdir/src/haptic/linux/*.c"
>			       have_haptic=yes]) ]) ])
>
>        dnl Set up files for the power library
>        AS_IF([test x$enable_power = xyes],
>	      [AS_CASE([$ARCH],
>		       [linux],
>		       [AC_DEFINE([SDL_POWER_LINUX], 1,[Description])
>		        SOURCES="$SOURCES $srcdir/src/power/linux/*.c"
>			have_power=yes]) ])
>
>	dnl Set up files for the thread library
>        AS_IF([test x$enable_threads = xyes -a x$use_pthreads != xyes -a x$use_pth != xyes -a x$ARCH = xirix],
>	      [AC_DEFINE([SDL_THREAD_SPROC], 1,[Description])
>	       SOURCES="$SOURCES $srcdir/src/thread/irix/*.c"
>	       SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_sysmutex.c"
>	       SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syscond.c"
>	       have_threads=yes])
>	dnl Set up files for the timer library
>	AS_IF([test x$enable_timers = xyes],
>	      [AC_DEFINE([SDL_TIMER_UNIX], 1,[Description])
>	       SOURCES="$SOURCES $srcdir/src/timer/unix/*.c"
>	       have_timers=yes]) ],
>	      [*-*-qnx*],
>	      [EXTRA_CFLAGS="-I/usr/include $CFLAGS"
>	       EXTRA_LDLAGS="-L/usr/lib $LDFLAGS"
>	       ARCH=qnx
>	       CHECK_VISIBILITY_HIDDEN
>	       CHECK_DUMMY_VIDEO
>	       CHECK_DISC_AUDIO
>	       CHECK_DUMMY_AUDIO
>	       CHECK_DLOPEN
>	       CHECK_PULSEAUDIO
>	       CHECK_ESD
>	       CHECK_NAS
>	       CHECK_PHOTON
>	       CHECK_QNX_GF
>	       CHECK_X11
>	       CHECK_OPENGL_X11
>	       CHECK_PTHREADS
>	       CHECK_CLOCK_GETTIME
>	       dnl Set up files for the audio library
>	       AS_IF([test x$enable_audio = xyes],
>		     [AC_DEFINE([SDL_AUDIO_DRIVER_QSA], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/audio/qsa/*.c"
>		      EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lasound"
>		      have_audio=yes])
>	       dnl Set up files for the timer library
>	       AS_IF([test x$enable_timers = xyes],
>		     [AC_DEFINE([SDL_TIMER_UNIX], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/timer/unix/*.c"
>		      have_timers=yes])
>	       dnl Setup files for the atomic operations
>	       AS_IF([test x$enable_atomic = xyes],
>		     [AC_DEFINE([SDL_ATOMIC_QNX], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/atomic/qnx/*.c"
>		      have_atomic=yes])
>	       dnl Set up dummy files for the joystick for now
>	       AS_IF([test x$enable_joystick = xyes],
>		     [AC_DEFINE([SDL_JOYSTICK_DUMMY], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/joystick/dummy/*.c"
>		      have_joystick=yes])
>	       dnl Set up dummy files for the haptic for now
>	       AS_IF([test x$enable_haptic = xyes],
>		     [AC_DEFINE([SDL_HAPTIC_DUMMY], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/haptic/dummy/*.c"
>		      have_haptic=yes]) ],
>	      [*-wince* | *-mingw32ce],
>	      [ARCH=win32
>	       CHECK_DUMMY_VIDEO
>	       CHECK_DISC_AUDIO
>	       CHECK_DUMMY_AUDIO
>	       CHECK_WIN32
>	       dnl SOURCES="$SOURCES $srcdir/src/video/gapi/*.c"
>	       dnl AC_DEFINE([SDL_VIDEO_DRIVER_GAPI], 1,[Description])
>	       AS_IF([test x$enable_video = xyes],
>		     [AC_DEFINE([SDL_VIDEO_DRIVER_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/video/win32/*.c"
>		      have_video=yes
>		      AC_ARG_ENABLE([render-gdi],
>				    [AS_HELP_STRING([--enable-render-gdi],
>						    [enable the GDI render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_gdi=yes])
>		      AS_IF([test x$enable_render_gdi = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_GDI], 1,[Description]) ])
>		      AC_ARG_ENABLE([render-gapi],
>				    [AS_HELP_STRING([--enable-render-gapi],
>						    [enable the GAPI/RAWFRAMEBUFFER render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_gapi=yes])
>		      AS_IF([test x$enable_render_gapi = xyes -a x$have_wince = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_GAPI], 1,[Description]) ])
>		      AC_ARG_ENABLE([render-ddraw],
>				    [AS_HELP_STRING([--enable-render-ddraw],
>						    [enable the Mobile DirectDraw render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_ddraw=yes])
>		      AS_IF([test x$enable_render_ddraw = xyes -a x$have_wince = xyes -a x$have_ddraw = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_DDRAW], 1,[Description]) ])
>		      AC_ARG_ENABLE([render-d3d],
>				    [AS_HELP_STRING([--enable-render-d3d],
>						    [enable the Direct3D render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_d3d=yes])
>		      enable_render_d3d=no
>		      AS_IF([test x$enable_render_d3d = xyes -a x$have_d3d = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_D3D], 1,[Description]) ]) ])
>	       dnl Set up files for the audio library
>	       AS_IF([test x$enable_audio = xyes],
>		     [AC_DEFINE([SDL_AUDIO_DRIVER_WINWAVEOUT], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/audio/windib/*.c"
>		      AS_IF([test x$have_dsound = xyes],
>			    [AC_DEFINE([SDL_AUDIO_DRIVER_DSOUND], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/audio/windx5/*.c"])
>		      have_audio=yes])
>	       dnl Set up files for the thread library
>	       AS_IF([test x$enable_threads = xyes],
>		     [AC_DEFINE([SDL_THREAD_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_sysmutex.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_syssem.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_systhread.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syscond.c"
>		      have_threads=yes])
>	       dnl Set up files for the timer library
>	       AS_IF([test x$enable_timers = xyes],
>		     [AC_DEFINE([SDL_TIMER_WINCE], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/timer/wince/*.c"
>		      have_timers=yes])
>	       dnl Set up files for the shared object loading library
>	       AS_IF([test x$enable_loadso = xyes],
>		     [AC_DEFINE([SDL_LOADSO_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/loadso/win32/*.c"
>		      have_loadso=yes])
>	       dnl Set up files for the system power library
>	       AS_IF([test x$enable_power = xyes],
>		     [AC_DEFINE([SDL_POWER_WINDOWS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/power/windows/*.c"
>		      have_power=yes])
>	       dnl Set up the system libraries we need
>	       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lcoredll -lcommctrl -lmmtimer"
>	       dnl The Win32 platform requires special setup
>	       SDLMAIN_SOURCES="$srcdir/src/main/win32/*.c"
>	       SDL_CFLAGS="$SDL_CFLAGS -Dmain=SDL_main -D_WIN32_WCE=0x420"
>	       SDL_LIBS="-lSDLmain $SDL_LIBS"],
>	      [*-*-cygwin* | *-*-mingw32*],
>	      [ARCH=win32
>	       AS_IF([test "$build" != "$host"], dnl cross-compiling
>		     [dnl Default cross-compile location
>		      ac_default_prefix=/usr/local/cross-tools/i386-mingw32],
>		     [dnl Look for the location of the tools and install there
>		      AS_IF([test "$BUILD_PREFIX" != ""],
>			    [ac_default_prefix=$BUILD_PREFIX]) ])
>	       CHECK_DUMMY_VIDEO
>	       CHECK_DISC_AUDIO
>	       CHECK_DUMMY_AUDIO
>	       CHECK_WIN32
>	       CHECK_GL_WIN32
>	       CHECK_DIRECTX
>	       dnl Set up files for the video library
>	       AS_IF([test x$enable_video = xyes],
>		     [AC_DEFINE([SDL_VIDEO_DRIVER_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/video/win32/*.c"
>		      have_video=yes
>		      AC_ARG_ENABLE([render-gdi],
>				    [AS_HELP_STRING([--enable-render-gdi],
>						    [enable the GDI render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_gdi=yes])
>		      AS_IF([test x$enable_render_gdi = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_GDI], 1,[Description]) ])
>		      AC_ARG_ENABLE([render-d3d],
>				    [AS_HELP_STRING([--enable-render-d3d],
>						    [enable the Direct3D render driver [[default=yes]] ]) ],
>				    [],
>				    [enable_render_d3d=yes])
>		      AS_IF([test x$enable_render_d3d = xyes -a x$have_d3d = xyes],
>			    [AC_DEFINE([SDL_VIDEO_RENDER_D3D], 1,[Description]) ]) ])
>	       dnl Set up files for the audio library
>	       AS_IF([test x$enable_audio = xyes],
>		     [AC_DEFINE([SDL_AUDIO_DRIVER_WINWAVEOUT], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/audio/windib/*.c"
>		      AS_IF([test x$have_dsound = xyes],
>			    [AC_DEFINE([SDL_AUDIO_DRIVER_DSOUND], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/audio/windx5/*.c"])
>		      have_audio=yes])
>	       dnl Set up files for atomic operations library
>	       AS_IF([test x$enable_atomic = xyes],
>		     [AC_DEFINE([SDL_ATOMIC_WIN32], [], [Description])
>		      SOURCES="$SOURCES $srcdir/src/atomic/win32/*.c"
>		      have_atomic=yes])
>	       dnl Set up files for the joystick library
>	       AS_IF([test x$enable_joystick = xyes],
>		     [AS_IF([test x$have_dinput = xyes],
>			    [AC_DEFINE([SDL_JOYSTICK_DINPUT], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/joystick/win32/SDL_dxjoystick.c"
>			     EXTRA_LDFLAGS="$EXTRA_LDFLAGS -ldinput8 -ldxguid -ldxerr8 -lole32"],
>			    [AC_DEFINE([SDL_JOYSTICK_WINMM], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/joystick/win32/SDL_mmjoystick.c"])
>		     have_joystick=yes])
>	       dnl TODO: One il should be enough
>	       AS_IF([test x$enable_haptic = xyes],
>		     [AS_IF([test x$have_dinput = xyes],
>			    [AC_DEFINE([SDL_HAPTIC_DINPUT], 1,[Description])
>			     SOURCES="$SOURCES $srcdir/src/haptic/win32/SDL_syshaptic.c"
>			     have_haptic=yes]) ])
>	       AS_IF([test x$enable_power = xyes],
>		     [AC_DEFINE([SDL_POWER_WINDOWS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/power/windows/SDL_syspower.c"
>		      have_power=yes])
>	       dnl Set up files for the thread library
>	       AS_IF([test x$enable_threads = xyes],
>		     [AC_DEFINE([SDL_THREAD_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_sysmutex.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_syssem.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/win32/SDL_systhread.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syscond.c"
>		      have_threads=yes])
>	       dnl Set up files for the timer library
>	       AS_IF([test x$enable_timers = xyes],
>		     [AC_DEFINE([SDL_TIMER_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/timer/win32/*.c"
>		      have_timers=yes])
>	       dnl Set up files for the shared object loading library
>	       AS_IF([test x$enable_loadso = xyes],
>		     [AC_DEFINE([SDL_LOADSO_WIN32], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/loadso/win32/*.c"
>		      have_loadso=yes])
>	       dnl Set up the system libraries we need
>	       dnl SDL 1.3 is unicode, and unicows emulates this on Windows 98/ME
>	       dnl You can get this here: http://libunicows.sourceforge.net/
>	       dnlEXTRA_LDFLAGS="$EXTRA_LDFLAGS -lunicows"
>	       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -luser32 -lgdi32 -lmsimg32 -lwinmm"
>	       dnl The Win32 platform requires special setup
>	       VERSION_SOURCES="$srcdir/src/main/win32/*.rc"
>	       SDLMAIN_SOURCES="$srcdir/src/main/win32/*.c"
>	       SDL_CFLAGS="$SDL_CFLAGS -Dmain=SDL_main"
>	       SDL_LIBS="-lmingw32 -lSDLmain $SDL_LIBS -mwindows"],
>	      [*-*-beos* | *-*-haiku*],
>	      [ARCH=beos
>	       ac_default_prefix=/boot/develop/tools/gnupro
>	       CHECK_DUMMY_VIDEO
>	       CHECK_DISC_AUDIO
>	       CHECK_DUMMY_AUDIO
>	       CHECK_BWINDOW
>	       CHECK_GL_BE
>	       dnl Set up files for the audio library
>	       AS_IF([test x$enable_audio = xyes],
>		     [AC_DEFINE([SDL_AUDIO_DRIVER_BEOSAUDIO], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/audio/baudio/*.cc"
>		      have_audio=yes])
>	       dnl Set up files for the joystick library
>	       AS_IF([test x$enable_joystick = xyes],
>		     [AC_DEFINE([SDL_JOYSTICK_BEOS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/joystick/beos/*.cc"
>		      have_joystick=yes])
>	       dnl Set up files for the thread library
>	       AS_IF([test x$enable_threads = xyes],
>		     [AC_DEFINE([SDL_THREAD_BEOS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/thread/beos/*.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_sysmutex.c"
>		      SOURCES="$SOURCES $srcdir/src/thread/generic/SDL_syscond.c"
>		      have_threads=yes])
>	       dnl Set up files for the timer library
>	       AS_IF([test x$enable_timers = xyes],
>		     [AC_DEFINE([SDL_TIMER_BEOS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/timer/beos/*.c"
>		      have_timers=yes])
>	       dnl Set up files for the shared object loading library
>	       AS_IF([test x$enable_loadso = xyes],
>		     [AC_DEFINE([SDL_LOADSO_BEOS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/loadso/beos/*.c"
>		      have_loadso=yes])
>	       dnl Set up files for the system power library
>	       AS_IF([test x$enable_power = xyes],
>		     [AC_DEFINE([SDL_POWER_BEOS], 1,[Description])
>		      SOURCES="$SOURCES $srcdir/src/power/beos/*.c"
>		      have_power=yes])
>	       dnl The BeOS platform requires special setup.
>	       SOURCES="$srcdir/src/main/beos/*.cc $SOURCES"
>	       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lroot -lbe -lmedia -lgame -ldevice -ltextencoding"],
>	       [*-*-darwin*],
>	       [dnl This could be either full "Mac OS X", or plain "Darwin" which is
>		dnl just the OS X kernel sans upper layers like Carbon and Cocoa.
>		dnl Next line is broken, and a few files below require Mac OS X (full)
>		ARCH=macosx
>		dnl Mac OS X builds with both the Carbon and OSX APIs at the moment
>		EXTRA_CFLAGS="$EXTRA_CFLAGS -DTARGET_API_MAC_CARBON"
>		EXTRA_CFLAGS="$EXTRA_CFLAGS -DTARGET_API_MAC_OSX"
>		dnl HACK: Reset EXTRA_LDFLAGS; the only thing it contains at this point
>		dnl is -lm which is not needed under Mac OS X. But for some reasons it
>		dnl also tends to contain spurious -L switches, which we don't want to
>		dnl use here or in sdl-config. Hence we reset it.
>		EXTRA_LDFLAGS=""
>		CHECK_VISIBILITY_HIDDEN
>		CHECK_DUMMY_VIDEO
>		CHECK_DISC_AUDIO
>		CHECK_DUMMY_AUDIO
>		CHECK_DLOPEN
>		dnl Set up files for the shared object loading library
>		dnl (this needs to be done before the dynamic X11 check)
>		AS_IF([test x$enable_loadso = xyes -a x$have_dlopen != xyes],
>		      [AC_DEFINE([SDL_LOADSO_DLCOMPAT], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/loadso/macosx/*.c"
>		       have_loadso=yes])
>		CHECK_COCOA
>		CHECK_X11
>		CHECK_GL_MAC
>		CHECK_OPENGL_X11
>		CHECK_PTHREADS
>		dnl Good optimization on Mac OS X, yes...
>		EXTRA_CFLAGS="$EXTRA_CFLAGS -falign-loops=16"
>		dnl Need this or things might misbuild on a G3.
>		EXTRA_CFLAGS="$EXTRA_CFLAGS -force_cpusubtype_ALL"
>		dnl Set up files for the audio library
>		AS_IF([test x$enable_audio = xyes],
>		      [AC_DEFINE([SDL_AUDIO_DRIVER_COREAUDIO], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/audio/macosx/*.c"
>		       have_audio=yes])
>		dnl Set up files for the atomic operations library
>		AS_IF([test x$enable_atomic = xyes],
>		      [AC_DEFINE([SDL_ATOMIC_MACOSX], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/atomic/macosx/*.c"
>		       have_atomic=yes])
>		dnl Set up files for the joystick library
>		AS_IF([test x$enable_joystick = xyes],
>		      [AC_DEFINE([SDL_JOYSTICK_IOKIT], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/joystick/darwin/*.c"
>		       have_joystick=yes])
>		dnl Set up files for the haptic library
>		AS_IF([test x$enable_haptic = xyes],
>		      [AC_DEFINE([SDL_HAPTIC_IOKIT], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/haptic/darwin/*.c"
>		       have_haptic=yes
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,ForceFeedback"])
>		dnl Set up files for the power library
>		AS_IF([test x$enable_power = xyes],
>		      [AC_DEFINE([SDL_POWER_MACOSX], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/power/macosx/*.c"
>		       have_power=yes])
>		dnl Set up files for the timer library
>		AS_IF([test x$enable_timers = xyes],
>		      [AC_DEFINE([SDL_TIMER_UNIX], 1,[Description])
>		       SOURCES="$SOURCES $srcdir/src/timer/unix/*.c"
>		       have_timers=yes])
>		dnl The Mac OS X platform requires special setup.
>		EXTRA_CFLAGS="$EXTRA_CFLAGS -fpascal-strings"
>		EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lobjc"
>		EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,Cocoa"
>		EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,Carbon"
>		EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,IOKit"
>		dnl If either the audio or CD driver is used, add the AudioUnit framework
>		AS_IF([test x$enable_audio = xyes],
>		      [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-framework,CoreAudio -Wl,-framework,AudioToolbox -Wl,-framework,AudioUnit"]) ],
>		      [*-riscos],
>		      [ARCH=riscos
>		       CHECK_OSS
>		       CHECK_PTHREADS
>		       dnl Set up files for the video library
>		       AS_IF([test x$enable_video = xyes],
>			     [AC_DEFINE([SDL_VIDEO_DRIVER_RISCOS], 1,[Description])
>			      SOURCES="$SOURCES $srcdir/src/video/riscos/*.c"
>			      SOURCES="$SOURCES $srcdir/src/video/riscos/*.S"
>			      have_video=yes])
>		       dnl Set up files for the joystick library
>		       AS_IF([test x$enable_joystick = xyes],
>			     [AC_DEFINE([SDL_JOYSTICK_RISCOS], 1,[Description])
>			      SOURCES="$SOURCES $srcdir/src/joystick/riscos/*.c"
>			      have_joystick=yes])
>		       dnl Set up files for the timer library
>		       AS_IF([test x$enable_timers = xyes],
>			     [AC_DEFINE([SDL_TIMER_RISCOS], 1,[Description])
>			      SOURCES="$SOURCES $srcdir/src/timer/riscos/*.c"
>			      have_timers=yes])
>		       dnl The RISC OS platform requires special setup.
>		       EXTRA_LDFLAGS="$EXTRA_LDFLAGS -ljpeg -ltiff -lpng -lz"],
>		      [AC_MSG_ERROR([Unsupported host:  Please add to configure.in ]) ])
>
>dnl Verify that we have all the platform specific files we need
>AS_IF([test x$have_joystick != xyes],
>      [AS_IF([test x$enable_joystick = xyes],
>	     [AC_DEFINE([SDL_JOYSTICK_DISABLED], 1,[Description]) ])
>       SOURCES="$SOURCES $srcdir/src/joystick/dummy/*.c"])
>AS_IF([test x$have_haptic != xyes],
>      [AS_IF([test x$enable_haptic = xyes],
>	     [AC_DEFINE([SDL_HAPTIC_DISABLED], 1,[Description]) ])
>       SOURCES="$SOURCES $srcdir/src/haptic/dummy/*.c"])
>AS_IF([test x$have_threads != xyes],
>      [AS_IF([test x$enable_threads = xyes],
>	     [AC_DEFINE([SDL_THREADS_DISABLED], 1,[Description]) ])
>       SOURCES="$SOURCES $srcdir/src/thread/generic/*.c"])
>AS_IF([test x$have_timers != xyes],
>      [AS_IF([test x$enable_timers = xyes],
>	     [AC_DEFINE([SDL_TIMERS_DISABLED], 1,[Description]) ])
>       SOURCES="$SOURCES $srcdir/src/timer/dummy/*.c"])
>AS_IF([test x$have_loadso != xyes],
>      [AS_IF([test x$enable_loadso = xyes],
>	     [AC_DEFINE([SDL_LOADSO_DISABLED], 1,[Description]) ])
>       SOURCES="$SOURCES $srcdir/src/loadso/dummy/*.c"])
>AS_IF([test x$SDLMAIN_SOURCES = x],
>      [SDLMAIN_SOURCES="$srcdir/src/main/dummy/*.c"])
>
>OBJECTS=`echo $SOURCES`
>DEPENDS=`echo $SOURCES`
>for EXT in asm cc m c S; do
>    OBJECTS=`echo "$OBJECTS" | sed 's,[[^ ]]*/$[[^ ]]*$\.'$EXT',$(objects)/\1.lo,g'`
>    DEPENDS=`echo "$DEPENDS" | sed 's,$[[^ ]]*$/$[[^ ]]*$\.'$EXT',\\
>$(objects)/\2.lo: \1/\2.'$EXT'\\
>	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) -MMD -MT \$@ -c \$< -o \$@,g'`
>done
>
>VERSION_OBJECTS=`echo $VERSION_SOURCES`
>VERSION_DEPENDS=`echo $VERSION_SOURCES`
>VERSION_OBJECTS=`echo "$VERSION_OBJECTS" | sed 's,[[^ ]]*/$[[^ ]]*$\.rc,$(objects)/\1.o,g'`
>VERSION_DEPENDS=`echo "$VERSION_DEPENDS" | sed 's,$[[^ ]]*$/$[[^ ]]*$\.rc,\\
>$(objects)/\2.o: \1/\2.rc\\
>	\$(WINDRES) \$< \$@,g'`
>
>SDLMAIN_OBJECTS=`echo $SDLMAIN_SOURCES`
>SDLMAIN_DEPENDS=`echo $SDLMAIN_SOURCES`
>SDLMAIN_OBJECTS=`echo "$SDLMAIN_OBJECTS" | sed 's,[[^ ]]*/$[[^ ]]*$\.c,$(objects)/\1.o,g'`
>SDLMAIN_DEPENDS=`echo "$SDLMAIN_DEPENDS" | sed 's,$[[^ ]]*$/$[[^ ]]*$\.c,\\
>$(objects)/\2.o: \1/\2.c\\
>	\$(LIBTOOL) --mode=compile \$(CC) \$(CFLAGS) \$(EXTRA_CFLAGS) -MMD -MT \$@ -c \$< -o \$@,g'`
>
>dnl Set runtime shared library paths as needed
>
>AS_IF([test "x$enable_rpath" = "xyes"],
>      [AS_IF([test $ARCH = bsdi -o $ARCH = freebsd -o $ARCH = irix -o $ARCH = linux -o $ARCH = netbsd],
>	     [SDL_RLD_FLAGS="-Wl,-rpath,\${libdir}"])
>       AS_IF([test $ARCH = solaris],
>	     [SDL_RLD_FLAGS="-R\${libdir}"]) ],
>      [SDL_RLD_FLAGS=""])
>
>AS_CASE(["$ARCH"],
>        [macosx],
>        [dnl Evil hack to allow static linking on Mac OS X
>	 SDL_STATIC_LIBS="\${libdir}/libSDL.a $EXTRA_LDFLAGS"],
>	[*],
>	[SDL_STATIC_LIBS="$SDL_LIBS $EXTRA_LDFLAGS"])
>
>dnl Expand the cflags and libraries needed by apps using SDL
>AC_SUBST([SDL_CFLAGS])
>AC_SUBST([SDL_LIBS])
>AC_SUBST([SDL_STATIC_LIBS])
>AC_SUBST([SDL_RLD_FLAGS])
>AS_IF([test x$enable_shared = xyes],
>      [ENABLE_SHARED_TRUE=
>       ENABLE_SHARED_FALSE="#"],
>      [ENABLE_SHARED_TRUE="#"
>       ENABLE_SHARED_FALSE=])
>AS_IF([test x$enable_static = xyes],
>      [ENABLE_STATIC_TRUE=
>       ENABLE_STATIC_FALSE="#"],
>      [ENABLE_STATIC_TRUE="#"
>       ENABLE_STATIC_FALSE=])
>AC_SUBST([ENABLE_SHARED_TRUE])
>AC_SUBST([ENABLE_SHARED_FALSE])
>AC_SUBST([ENABLE_STATIC_TRUE])
>AC_SUBST([ENABLE_STATIC_FALSE])
>
>dnl Expand the sources and objects needed to build the library
>AC_SUBST([ac_aux_dir])
>AC_SUBST([INCLUDE])
>AC_SUBST([OBJECTS])
>AC_SUBST([DEPENDS])
>AC_SUBST([VERSION_OBJECTS])
>AC_SUBST([VERSION_DEPENDS])
>AC_SUBST([SDLMAIN_OBJECTS])
>AC_SUBST([SDLMAIN_DEPENDS])
>AC_SUBST([BUILD_CFLAGS])
>AC_SUBST([EXTRA_CFLAGS])
>AC_SUBST([BUILD_LDFLAGS])
>AC_SUBST([EXTRA_LDFLAGS])
>AC_SUBST([WINDRES])
>
>AC_CONFIG_FILES([Makefile sdl-config SDL.spec sdl.pc])
>
>AC_OUTPUT

Actions: View

Attachments on bug 804: 398 | 399

We are currently migrating Bugzilla to GitHub issues.Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.

We are currently migrating Bugzilla to GitHub issues.
Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.
When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.