We are currently migrating Bugzilla to GitHub issues.
Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.
When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.

CMake.patch

CMake.patch (text/plain), 3.29 KB, created by David Demelier on 2018-11-14 09:25:47 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: David Demelier

Created: 2018-11-14 09:25:47 UTC

Size: 3.29 KB

patch

obsolete

># HG changeset patch
># User David Demelier <markand@malikania.fr>
># Date 1542185001 -3600
>#      Wed Nov 14 09:43:21 2018 +0100
># Node ID 558a3cd1c4c86cfc3cfb54e098f1cf7694d956f7
># Parent  cc76f146e613b74aff1f7903be02cd88921760dd
>Add CMake support
>
>diff -r cc76f146e613 -r 558a3cd1c4c8 CMakeLists.txt
>--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
>+++ b/CMakeLists.txt	Wed Nov 14 09:43:21 2018 +0100
>@@ -0,0 +1,90 @@
>+if(${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
>+  message(FATAL_ERROR "Prevented in-tree built. Please create a build directory outside of the SDL_net source code and call cmake from there")
>+endif()
>+
>+##### general #####
>+cmake_minimum_required(VERSION 3.0)
>+project(SDL_net C)
>+
>+include(GNUInstallDirs)
>+include(CMakePackageConfigHelpers)
>+
>+find_package(SDL2 REQUIRED)
>+find_package(PkgConfig QUIET)
>+
>+set(SDL_NET_MAJOR_VERSION 2)
>+set(SDL_NET_MINOR_VERSION 0)
>+set(SDL_NET_MICRO_VERSION 1)
>+set(SDL_NET_INTERFACE_AGE 0)
>+set(SDL_NET_BINARY_AGE 1)
>+set(SDL_NET_VERSION "${SDL_NET_MAJOR_VERSION}.${SDL_NET_MINOR_VERSION}.${SDL_NET_MICRO_VERSION}")
>+
>+##### library generation #####
>+add_library(SDL2_net SDLnet.c SDLnetTCP.c SDLnetUDP.c SDLnetselect.c SDLnetsys.h SDL_net.h)
>+target_link_libraries(SDL2_net SDL2::SDL2)
>+target_include_directories(SDL2_net PUBLIC $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/SDL2>)
>+
>+if (CMAKE_SYSTEM_NAME MATCHES Windows)
>+  target_link_libraries(SDL2_net ws2_32 iphlpapi)
>+endif ()
>+
>+install(
>+  TARGETS SDL2_net
>+  EXPORT sdl2_net-targets
>+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
>+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
>+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
>+)
>+install(
>+  FILES SDL_net.h
>+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/SDL2
>+)
>+
>+##### export files #####
>+if (APPLE)
>+  set(PKG_PREFIX "SDL2_net.framework/Resources")
>+elseif (WIN32)
>+  set(PKG_PREFIX "cmake")
>+else ()
>+  set(PKG_PREFIX "lib/cmake/SDL2_net")
>+endif ()
>+
>+write_basic_package_version_file("${CMAKE_BINARY_DIR}/sdl2_net-config-version.cmake"
>+  VERSION ${SDL_NET_VERSION}
>+  COMPATIBILITY AnyNewerVersion
>+)
>+
>+install(
>+  EXPORT sdl2_net-targets
>+  FILE sdl2_net-targets.cmake
>+  NAMESPACE SDL2::
>+  DESTINATION ${PKG_PREFIX}
>+)
>+install(
>+  FILES
>+    ${CMAKE_CURRENT_SOURCE_DIR}/sdl2_net-config.cmake
>+    ${CMAKE_BINARY_DIR}/sdl2_net-config-version.cmake
>+  DESTINATION ${PKG_PREFIX}
>+  COMPONENT Devel
>+)
>+
>+##### pkg-config #####
>+if (PKG_CONFIG_FOUND)
>+  set(SDL_VERSION 2.0.0)
>+  set(prefix ${CMAKE_INSTALL_PREFIX})
>+  set(exec_prefix "\${prefix}")
>+  set(libdir "\${exec_prefix}/lib${LIB_SUFFIX}")
>+  set(bindir "\${exec_prefix}/bin")
>+  set(includedir "\${prefix}/include")
>+
>+  configure_file("${SDL_net_SOURCE_DIR}/SDL2_net.pc.in"
>+    "${SDL_net_BINARY_DIR}/SDL2_net.pc" @ONLY)
>+
>+  if (CMAKE_SYSTEM_NAME MATCHES FreeBSD)
>+    # FreeBSD uses ${PREFIX}/libdata/pkgconfig
>+    install(FILES ${SDL_net_BINARY_DIR}/SDL2_net.pc DESTINATION "libdata/pkgconfig")
>+  else ()
>+    install(FILES ${SDL_net_BINARY_DIR}/SDL2_net.pc
>+      DESTINATION "lib${LIB_SUFFIX}/pkgconfig")
>+  endif ()
>+endif ()
>diff -r cc76f146e613 -r 558a3cd1c4c8 sdl2_net-config.cmake
>--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
>+++ b/sdl2_net-config.cmake	Wed Nov 14 09:43:21 2018 +0100
>@@ -0,0 +1,3 @@
>+include(CMakeFindDependencyMacro)
>+find_dependency(SDL2)
>+include("${CMAKE_CURRENT_LIST_DIR}/sdl2_net-targets.cmake")

Actions: View

Attachments on bug 4381: 3489

We are currently migrating Bugzilla to GitHub issues.Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.

We are currently migrating Bugzilla to GitHub issues.
Any changes made to the bug tracker now will be lost, so please do not post new bugs or make changes to them.
When we're done, all bug URLs will redirect to their equivalent location on the new bug tracker.